admin.vbs 以管理员身份运行程序的vbs命令
2018-10-12 14:11
686 查看
'以管理员身份运行程序的命令admin.vbs
Set objWMIServices = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
Set objWbemObjectSet = objWMIServices.ExecQuery(_
"SELECT * FROM Win32_Process WHERE " &_
"ExecutablePath='" & Replace(WScript.FullName,"\","\\") & "' and " & _
"CommandLine LIKE '%" & WScript.ScriptName & "%'")
for each objWbemObject in objWbemObjectSet
cmdline = objWbemObject.CommandLine
next
if WScript.Arguments.Count then
file = WScript.Arguments(0)
if file="/?" then
call ShowHelp()
WScript.Quit
end if
Set RegEx = new RegExp
RegEx.IgnoreCase = true
RegEx.Global = true
RegEx.Pattern = "\\|\/|\||\(|\)|\[|\]|\{|\}|\^|\$|\.|\*|\?|\+"
temp1 = RegEx.Replace(WScript.ScriptName, "\$&")
temp2 = RegEx.Replace(file, "\$&")
RegEx.Global = false
RegEx.Pattern = "^.*?" & temp1 & "[""\s]*" & temp2 & """?\s*"
args = RegEx.Replace(cmdline, "")
'WScript.Echo file, args
else
file = "cmd.exe"
'args = "/k cd /d """ & CreateObject("WScript.Shell").CurrentDirectory & Chr(34)
end if
'核心代码
Set sh = CreateObject("Shell.Application")
call sh.ShellExecute( file, args, , "runas" )
function ShowHelp()
dim HelpStr
HelpStr = "以管理员身份运行程序。" & vbCrLf _
& vbCrLf _
& WScript.ScriptName & " [program] [parameters]..." & vbCrLf _
& vbCrLf _
& "program 要运行的程序" & vbCrLf _
& "parameters 传递给 program 的参数" & vbCrLf _
& vbCrLf
WScript.Echo HelpStr
end function
建议放到%SystemRoot%\system32目录下,对喜欢玩cmd而且操作系统是win7的人有点用处。
偶尔用到某些命令(如reg.exe)需要管理员权限,直接在cmd中 admin reg add ... 即可。
相关文章推荐
- Runas命令:能让域用户/普通User用户以管理员身份运行指定程序。
- Runas命令能让域用户/普通User用户以管理员身份运行指定程序
- Runas命令:能让域用户/普通User用户以管理员身份运行指定程序
- 让程序自动以管理员身份运行(用到了DuplicateToken,模拟管理员的身份,不可思议)
- win7上运行某程序的时候,如果这个程序需要以管理员的身份运行,那么就会有“用户帐户控制”的提示:“您想允许来自...发布者的以下程序对此计算机进行更改吗?”请问,win7如何知道哪些程序需要以管理员的身份运行?
- 让程序在win7下运行时弹出"以管理员身份运行"
- 易语言 让编译的程序自动以管理员身份运行
- windows下默认以管理员身份运行程序
- C#如何以管理员身份运行程序
- win7下让程序默认以管理员身份运行
- Winform程序在win7中默认以管理员身份运行
- C#通过app.manifest使程序以管理员身份运行
- C#默认以管理员身份运行程序
- VS生成请求以管理员身份运行的程序
- django-admin.py不是内部或外部命令,也不是可运行的程序或批处理文件
- 用管理员身份运行程序
- 【win8管理员身份运行程序如何设置?】
- 如何以管理员身份自动运行 程序
- 如何以管理员身份运行命令提示符打开DOS
- .net 程序以管理员身份运行