CorelDRAW VBA - 读取XML文件，根据内容批量创建图形

目的

这篇教程将教会你如何使用 CorelDRAW VBA 来读取 XML 文件，并通过读取的内容来动态创建指定宽度和高度的矩形。

准备一个XML文件

打开记事本，粘贴以下内容，然后保存文件，文件名输入

shape.xml

，保存类型选择“所有文件”。将这个文件保存到

d:\temp\shape.xml

或者你指定的其他位置（如果使用自定义位置，请在下面的VBA代码中修改成自己的XML文件路径）。

在这个XML文件中，我们使用

shape

节点记录了一个矩形的简单信息，包括 width（宽度）、height（高度）和 title（标题），一共定义了 3 个简单的矩形信息，内容如下所示：

<?xml version="1.0" encoding="UTF-8"?>
<shapes>
<shape>
<width>200</width>
<height>100</height>
<title>矩形1</title>
</shape>
<shape>
<width>300</width>
<height>180</height>
<title>矩形2</title>
</shape>
<shape>
<width>400</width>
<height>220</height>
<title>矩形3</title>
</shape>
</shapes>

在宏编辑器中粘贴以下代码

如果你还不知道怎么创建自己的宏工程（GMS工程），请先阅读 CorelDRAW VBA - 创建GMS宏工程 这篇文章，然后将下面的代码拷贝并运行。

'========================================================================================
' 主函数（默认对外暴露的运行入口）
' @author: Zebe
' @date: 2017/12/11
'========================================================================================
Sub main()
readXMLAndCreateShape "d:\temp\shape.xml" ' 调用过程（请注意XML文件路径）
End Sub

'========================================================================================
' 读取XML文件并创建图形
' @author: Zebe
' @date: 2017/12/11
'========================================================================================
Private Sub readXMLAndCreateShape(filePath As String)
' 载入XML文件
Dim xmlDom
Set xmlDom = CreateObject("MSXML.DOMDocument")
xmlDom.Load (filePath)
xmlDom.async = False ' 关闭异步读取，设置为同步读取（即：这句代码会阻塞，直到文件读取完）

' 节点变量声明
Dim shapeNodes, widthNodes, heightNodes, titleNodes
Set shapeNodes = xmlDom.SelectNodes("//shape")
Set widthNodes = xmlDom.SelectSingleNode("//width")
Set heightNodes = xmlDom.SelectSingleNode("//height")
Set titleNodes = xmlDom.SelectSingleNode("//title")

' 遍历所有shape节点
Dim i As Integer, j As Integer
For i = 0 To shapeNodes.Length - 1
' 取出每个shape节点下的子节点（根据索引序号去取）
Dim width As Integer, height As Integer, title As String
width = shapeNodes.Item(i).ChildNodes(0).Text
height = shapeNodes.Item(i).ChildNodes(1).Text
title = shapeNodes.Item(i).ChildNodes(2).Text
'MsgBox ("width=" & width & ", height=" & height & ", title=" & title)
createShape width, height, title
Next i

' 释放已经加载的DOM对象所占用的内存
Set xmlDom = Nothing
End Sub

'========================================================================================
' 创建图形（这个方法中没有用到 title 参数，可根据需要使用，例如设置备注）
' @author: Zebe
' @date: 2017/12/11
'========================================================================================
Private Sub createShape(width As Integer, height As Integer, title As String)
' 如果没有活动文档，则自动创建一个文档，并设置文档单位为mm
If ActiveDocument Is Nothing Then
Application.CreateDocument
ActiveDocument.Unit = cdrMillimeter
End If
' 在页面左下角（坐标0,0）开始，创建指定宽高的矩形
ActiveDocument.ActivePage.ActiveLayer.CreateRectangle2 0, 0, width, height
End Sub

代码说明

Set xmlDom = CreateObject("MSXML.DOMDocument")

创建了一个XML文档模型对象

SelectNodes

方法用来选择某个节点集合

SelectSingleNode

方法用来选择单个节点

节点集合.Item(i)

这种调用方法是用来访问某个节点集合中的第 i 个元素

ChildNodes(x)

用来获取某个节点的第 x 个子节点

原创声明：本文首发于个人CorelDRAW VBA博客，请尊重文章版权。

转载请注明原文链接：http://www.cdrvba.com/coreldraw-vba-read-xml-file/