学习uboot前奏之hardware-arm基础知识[s3c2440]

一直想利用S3C2440系统的学习uboot和linux内核，但是一直没有坚持下来，之前都是学习零碎的知识，因为没有记录下来，后来基本都忘了，现在想把他们记录下，希望能坚持下去。

下面是ARM汇编的点灯程序，以及汇编后内容。这一篇内容旨在学习下一些基本但是后面会用到的ARM知识

.text
.global _start
_start:
ldr     r0, =0x56000010     @ WATCHDOG寄存器地址
mov     r1, #0x0
str     r1, [r0]            @写入0，禁止WATCHDOG，否则CPU会不断重启

LDR     R0,=0x56000050      @ R0设为GPFCON寄存器。此寄存器
@ 用于选择端口F各引脚的功能：

MOV     R1,#0x00001500      @0x1500设置GPF4,5,6为输出
STR     R1,[R0]
@ 设置GPF4,5,6为输出口,
LDR     R0,=0x56000054      @ R0设为GPFDAT寄存器，控制灯的亮灭

MOV     R1,#0x00000000

STR     R1,[R0]
MAIN_LOOP:
B       MAIN_LOOP

下面是对应的汇编后的程序

00000000 <_start>:
0:   e59f0020    ldr r0, [pc, #32]   ; 28 <.text+0x28>
4:   e3a01000    mov r1, #0  ; 0x0
8:   e5801000    str r1, [r0]
c:   e59f0018    ldr r0, [pc, #24]   ; 2c <.text+0x2c>
10:   e3a01c15    mov r1, #5376   ; 0x1500
14:   e5801000    str r1, [r0]
18:   e59f0010    ldr r0, [pc, #16]   ; 30 <.text+0x30>
1c:   e3a01000    mov r1, #0  ; 0x0
20:   e5801000    str r1, [r0]

00000024 <MAIN_LOOP>:
24:   eafffffe    b   24 <MAIN_LOOP>
28:   56000010    undefined
2c:   56000050    undefined
30:   56000054    undefined

LDR

大范围地址读取伪指令，用于加载32位立即数或一个地址值到指定寄存器，在汇编编译源程序时被替换成合适的指令，若加载的数没有超过MOV或者MVN范围，则可用之代替LDR,否则汇编器将常量放入子池，并使用一条程序相对的LDR指令读出量。

ldr     r0, =0x56000010     @ WATCHDOG寄存器地址
mov     r1, #0x0

被汇编成

0:   e59f0020    ldr r0, [pc, #32]   ; 28 <.text+0x28>
4:   e3a01000    mov r1, #0  ; 0x0

28:   56000010    undefined
2c:   56000050    undefined
30:   56000054    undefined

可以看出

ldr r0, =0x56000010，立即数被放到字池中，并利用根据pc指针做相对位移取出立即数

位置无关代码

位置无关代码，即该段代码无论放在内存的哪个地址，都能正确运行。究其原因，是因为代码里没有使用绝对地址，都是相对地址。

位置无关的写法:

B指令

B指令接受一个相对地址，因此在汇编里用B跳转到一个标号时，实际编译的结果是个相对跳转。

相对地址有个范围限制，即目标不能太远，一般目标放在同一个文件里是肯定可以的。

_start:

b _reset

_reset:

…

BL

BL用于调用函数，也是一个相对跳转

ADR

获取标号的地址，在编译时会使用PC+偏移的方式得到该位置的地址。例如，当TEXT_BASE是0时

SMRDATA可能被放在0x100的位置，当TEXT_BASE为0x30000000时放在0x30000100的位置。使用ADR

总能获取正确的位置，与程序的加载地址无关。

ADR R0, SMRDATA
SMRDATA:
.word  0x22111120
.word  0x00002F50
.word  0x00000700
(相应的, LDR Rn, =LABEL是位置相关的)

LDR

当加标号时，LDR可以用于伪指令，也可以真指令。

真指令: (标号前不加=号，表示取标号处的值)

LDR R0,  SDRDATA

实际被编译为LDR R0, [PC, #NN]，其中NN是目标的相对距离

伪指令: (标号前加=号，取标号的地址)

LDR R0, = SDRDATA

实际编译的时候的时候，会在某位置存处SDRDATA的值，然后用一个LDR取出来。

显然，用LDR时，加不加=号有很大区别。

无=号：取该标号处的值，位置无关

有=号：取该标号的地址，位置相关

举例分析

例1：中断向量跳转

_start:
b       reset
ldr    pc, _undefined_instruction
ldr    pc, _software_interrupt
ldr    pc, _prefetch_abort
ldr    pc, _data_abort
ldr    pc, _not_used
ldr    pc, _irq
ldr    pc, _fiq

_undefined_instruction:    .word undefined_instruction
_software_interrupt:    .word software_interrupt
_prefetch_abort:    .word prefetch_abort
_data_abort:        .word data_abort
_not_used:        .word not_used
_irq:            .word irq
_fiq:            .word fiq

其中，

ldr pc, _irq，由于没加=号，表示取值_irq处的值放在pc里 (位置无关)
_irq:  .word irq ，表示_irq存放的值是irq的绝对地址(位置有关)

例2:

bl  main ; 位置无关
ldr pc, =main; 把main的地址放在pc，位置相关

例3: 静态变量

_MAGIC_NUM:
.word 0x12345678
取值
LDR  R0, _MAGIC_NUM  ; 位置无关

例4: 存放标号绝对地址(绝对地址是编译的时候已经固定)

_OS_Running_p:
.word  OS_Runing

则_OS_Running_p存放的是标号OS_Running的绝对地址

例5: 显式LDR和隐式LDR

以给某C中的变量的g_num赋值为例

(1) 使用伪指令LDR，即为隐式

LDR R0, =g_num @取g_num的地址到R0

MOV R1, #10

STR R1, R0

(2) 显式赋值

先定义一个变量p_g_num，用于保存g_num的地址

p_g_num:
.word   g_num   @ g_num的绝对地址
然后赋值
LDR R0, p_g_num
MOV R1, #10
STR R1,  R0

显然，两者其实一样，伪指令被展开后其实就是(2)的样子。

不同点在于：在多次引用的时候，如果使用伪指令，则会有多个临时定义。所以，

在多次引用的时候应该使用显式定义。

例6: 使用LinkScript中的变量

这种情形和例5相同

1) LinkScript中定义了两个位置

{
__bss_start = .;
.bss : { *(.bss) }
_end = .;
}

2) 定义两个变量，用于存处这两个位置

.globl _bss_start
_bss_start:
.word __bss_start

.globl _bss_end
_bss_end:
.word _end

3) 使用这两个位置

ldr    r0, _bss_start        /* find start of bss segment        */
ldr    r1, _bss_end        /* stop here                        */