汇编语言程序设计

寻址方式在结构化数据访问中的应用

本文来自王爽著《汇编语言（第三版）》实验7

问题描述

power idea公司从1975年成立一直到1995年的基本情况如下:

年份	收入（千美元）	雇员（人）	人均收入（千美元）
1975	16	3	?
1976	22	7	?
1977	382	9	?
…	…	…	…
1995	5937000	17800	?

编程，将data段中的数据按如下格式写入到table段中，并计算21年中的人均收入（取整），结果也按照下面的格式保存在table段中。

编程思路

将data段的数据看作多个数组，table中的数据看作一个结构性数据的数组，每个结构型数据中包含多个数据项。

用bx定位每个结构型数据，立即数idata定位数据项，用si定位data段数组元素即可。要用到寄存器相对寻址[bx+idata]。

代码实现

assume  cs:codesg,ds:data,es:table

data segment
db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
db '1993','1994','1995'
;偏移地址范围0-53h，表示21个年份的21个字符串
dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
;偏移地址范围54h-0a7h，表示21年公司总收入的21个dword型数据
dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
dw 11542,14430,15257,17800
;偏移地址范围0a8h-0d1h，表示21年公司雇员人数的21个word型数据
data ends

table segment
db 21 dup('year summ ne ?? ')
table ends

codesg  segment

start:  mov ax,data
mov ds,ax
mov ax,table
mov es,ax
;---------------保存年份--------------------------------
mov si,0
mov bx,0
mov cx,21
;保存年份前两字节
s0: mov ax,[si]
mov es:[bx],ax
;保存年份后两字节
mov ax,[si+2]
mov es:[bx+2],ax
add si,4

add bx,10h
loop s0
;---------------保存总收入-----------------------------
mov si,54h
mov bx,0
mov cx,21
;保存总收入的前两字节
s1: mov ax,[si]
mov es:[bx+5],ax
;保存总收入的后两字节
mov ax,[si+2]
mov es:[bx+5+2],ax
add si,4

add bx,10h
loop s1
;----------------保存雇员数------------------------------
mov si,0a8h
mov bx,0
mov cx,21

s2: mov ax,[si]
mov es:[bx+0ah],ax
add si,2

add bx,10h
loop s2
;-------------计算并保存人均收入-------------------------

mov bx,0
mov cx,21

s3: mov ax,es:[bx+5]
mov dx,es:[bx+5+2]
div word ptr es:[bx+0ah]
mov es:[bx+0dh],ax

add bx,10h
loop s3
;---------------------------------------------------------------
mov ax,4c00h
int 21h

codesg  ends

end start

总结

这里的汇编程序就相当于C程序中给结构体数组赋值。汇编中的一些寻址方式（比如：[bx+idata],[bx+si],[bx+si+idata]）的操作和高级语言中的数组，结构体“太相似”了。因此要完成这个程序并不困难。

另外，明天汇编语言程序设计这门课就要期末考试了，我平时不会在博客上贴上汇编的代码，今天就算个福利，把自己略显幼稚的汇编代码贴上，希望大家都能在考试中取得好成绩。