msgX消息发送增强工具[下载]

熟悉命令行工具msg的人都知道，它发送的消息只能单行显示，如果你希望以多行的形式来显示消息是不行的。经过几天时间研究，我开发了一个增强版的消息发送工具msgX，它仍是以msg为基础，只要能用msg的地方就能使用msgX，使用方法也基本相同。下面是msgX的源代码，如有问题欢迎各位大虾指正。

::Based on MSG.EXE
::Designed By Computer Studio Of Zhou Zhou On 2016.7.7
@echo off
if "%1"=="" goto HELP
if "%1"=="/?" goto HELP
if "%2"=="" goto HELP
echo.%2 | findstr /I /C:"/M:" >nul&& set msgx_n=2&& set msgx_a=%2&& goto RUN
echo.%3 | findstr /I /C:"/M:" >nul&& set msgx_n=3&& set msgx_a=%3&& goto RUN
echo.%4 | findstr /I /C:"/M:" >nul&& set msgx_n=4&& set msgx_a=%4&& goto RUN
echo.%5 | findstr /I /C:"/M:" >nul&& set msgx_n=5&& set msgx_a=%5&& goto RUN
echo.%6 | findstr /I /C:"/M:" >nul&& set msgx_n=6&& set msgx_a=%6&& goto RUN
msg %username% /w " msgX错误：/M 参数缺失！"&goto HELP

:HELP
echo 将消息发送给用户。
echo.
echo MSGX {username ^| sessionname ^| sessionid ^| @filename ^| *}
echo [/SERVER:servername] [/TIME:seconds] [/V] [/W] [/M:message1]{\n}[message2]...
echo.
echo username 标识指定的用户名。
echo sessionname 会话名。
echo sessionid 会话 ID。
echo @filename 识别这样一个文件，该文件含有将所发消息发送到的用户
echo 名、会话名和会话标识号的列表。
echo * 给指定服务器上的所有会话发送信息。
echo /SERVER:servername 要联系的服务器(默认值是当前值)。
echo /TIME:seconds 等待接收器确认消息的时间延迟。
echo /V 显示有关执行的操作的信息。
echo /W 等待用户的响应，跟 /V 一起有用。
echo message 要发送的消息。如果没有指定，发出提示，或者从 stdin
echo 读取。
echo \n 换行符
echo.
echo 在批处理中要用call命令来调用，且需启用setlocal enabledelayedexpansion
echo 发送消息包含空格的必须用双引号""括起来，如 MSGX * /M:"Nice to meet you!"
echo.
pause
goto eof

:RUN
::setlocal enabledelayedexpansion
echo. !msgx_a! |findstr /I /c:"msgx_a" >nul&& msg %username% /w " msgX错误：setlocal enabledelayedexpansion 未启用" && goto eof
set msgx_a=!msgx_a:/M:=!
rem 下面的空行不能省略
set msgx_a=!msgx_a:\n=^

!
if "%msgx_n%"=="2" msg %1 !msgx_a!
if "%msgx_n%"=="3" msg %1 %2 !msgx_a!
if "%msgx_n%"=="4" msg %1 %2 %3 !msgx_a!
if "%msgx_n%"=="5" msg %1 %2 %3 %4 !msgx_a!
if "%msgx_n%"=="6" msg %1 %2 %3 %4 %5 !msgx_a!
set msgx_a=
set msgx_n=

:eof

点击下面的附件，可下载“msgX消息发送增强工具”。
本文出自 “舟舟电脑工作室” 博客，请务必保留此出处http://conducer.blog.51cto.com/841262/1814366