SAS学习笔记：创建图表

 /* Vertical Bar Chart Representing a Frequency Count  */

goptions reset=all;/**恢复默认设置，消除之前图形的标题脚注*/

proc gchart data=orion.staff;

   vbar Job_Title;

   where Job_Title =:'Sales Rep';

   title 'Number of Employees by Job Title';

run;

quit;

 

  /* Three-dimensional Horizontal Bar Chart  */

  

goptions reset=all;

proc gchart data=orion.staff;

   hbar3d Job_Title;

   title 'Number of Employees by Job Title';

   where Job_Title =:'Sales Rep';

run;

quit;

 /* Suppress the Display of Statistics on Horizontal Bar Charts  */

 

goptions reset=all;

proc gchart data=orion.staff;

   hbar3d Job_Title / nostats; /***nostats:不显示统计量**/

   title 'Number of Employees by Job Title';

   where Job_Title =:'Sales Rep';

run;

quit;

            

 /* Using a Numeric Chart Variable  */ 

goptions reset=all;

proc gchart data=orion.staff;

   vbar3d salary / autoref;

   where Job_Title =:'Sales Rep';

   format salary dollar9.;

   title 'Salary Distribution Midpoints for Sales Reps';

run;

quit;

 

 /* Specifying Ranges for a Numeric Chart Variable 

    and Adding Reference Lines  */

 

goptions reset=all;

proc gchart data=orion.staff;

   hbar3d salary/levels=5 range autoref nostats; /*划分5个区间，每个区间显示两端点值，*/

   where Job_Title =:'Sales Rep';

   format salary dollar9.;

   title 'Salary Distribution Ranges for Sales Reps';

run;

quit;

 /* Creating Bar Charts Based on Statistics  */

 

goptions reset=all;

proc gchart data=orion.staff;

   vbar Job_Title / sumvar=salary type=mean;/*用每个Job_Title的salary的均值代表图形的高度，type默认值为sum*/

   where Job_Title =:'Sales Rep';

   format salary dollar9.;

   label Job_Title='Job Title'

         Salary='Salary';

   title 'Average Salary by Job Title';

run;

quit;

   

 /* Assigning a Different Color to Each Bar */

goptions reset=all;

proc gchart data=orion.staff;

   vbar Job_Title / sumvar=salary type=mean patternid=midpoint mean;/**patternid=midpoint把值显示在每个条图形顶部*/

   where Job_Title =:'Sales Rep';

   format salary dollar9.;

   title 'Average Salary by Job Title';

run;

quit; 

    

 /* Dividing Bars into Subgroups  */

goptions reset=all;

proc gchart data=orion.staff;

   vbar Job_Title/subgroup=Gender;/*subgroup=选项：对图形按Gender分段：形式如下图1*/

   where Job_Title =:'Sales Rep';

   title 'Frequency of Job Title, Broken Down by Gender';

run;
quit;

     

 /*  Grouping Bars */

 

goptions reset=all;

proc gchart data=orion.staff;

   vbar gender/group=Job_Title patternid=midpoint;/*group=选项对图形分组*/

   where Job_Title =:'Sales Rep';

   title 'Frequency of Job Gender, Grouped by Job Title';

run;

quit;

 

 /* Creating Multiple Pie Charts Using RUN-Group Processing  */

 

goptions reset=all;

proc gchart data=orion.staff;

   pie Job_Title;

   where Job_Title =:'Sales Rep';

   title 'Frequency Distribution of Job Titles';

   title2 '2-D Pie Chart';

run;

   pie3d Job_Title / noheading;

   title2 '3-D Pie Chart';

run;

quit;