windows配置网卡IP脚本和配置路由条目、默认路由

    我们公司有专线wifi，回到家里里用自己的路由wifi，每次都要手动配置，好麻烦，所以写了脚本  .bat 。

    脚本如下：

@echo off 

:main 

cls 

echo =============IP配置脚本============= 

echo. 

echo 1.将IP设置为公司用的IP 请按 1 

echo 2.将IP设置为自动获取 请按 2 

echo 3.查看当前IP设置 请按 3 

echo 4.退出 请按 4 

echo. 

set NIC="无线网络连接" 

set /p choice=请选择您的操作： 

 

echo. 

if "%choice%"=="1" goto stcip 

if "%choice%"=="2" goto dycip 

if "%choice%"=="3" goto lookip 

if "%choice%"=="4" goto end 

 

goto main 

 

:stcip 

rem **************************************************** 

rem IP配置脚本 

rem NIC是网络连接名，一般为"本地连接"或"本地连接 2"等 

rem IP是网卡ip地址，GW是默认网关 

rem MASK是子网掩码 

rem DNS1和DNS2分别是首选和备用DNS服务器 

rem **************************************************** 

set IP="192.168.255.11" 

set GW="192.168.255.1" 

set MASK="255.255.255.0" 

rem set DNS1="218.2.135.1" 

rem set DNS2="61.147.37.1" 

echo -------------------------------- 

echo 下面将把网卡%NIC%设为如下地址：         

echo IP地址:          %IP% 

echo 子网掩码:        %MASK% 

echo 默认网关:        %GW% 

rem echo 首选DNS服务器：  %DNS1% 

rem echo 备用DNS服务器:    %DNS2% 

echo -------------------------------- 

echo 用恒网IP开始设置网卡，请稍等数秒...... 

netsh interface ip set address %NIC% static %IP% %MASK% %GW% 1 

rem echo 开始设置DNS...... 

rem netsh interface ip set dns %NIC% static %DNS1% primary 

rem echo 开始设置备用DNS...... 

rem netsh interface ip add dns %NIC% %DNS2% 

echo 设置完毕! 

 

CHOICE /C YN /M "退出请按 Y，返回菜单请按 N。"  

if errorlevel 2 goto main 

if errorlevel 1 goto end  

 

:dycip 

echo 将网卡设为DHCP自动获取IP 

echo 开始设置网卡，请稍等数秒...... 

netsh interface ip set address %NIC% source = dhcp 

netsh interface ip set dns %NIC% source = dhcp  

echo 设置完毕! 

CHOICE /C YN /M "退出请按 Y，返回菜单请按 N。"  

if errorlevel 2 goto main 

if errorlevel 1 goto end  

 

:lookip 

echo 查看网卡参数 

ipconfig /all 

CHOICE /C YN /M "退出请按 Y，返回菜单请按 N。"  

if errorlevel 2 goto main 

if errorlevel 1 goto end  

 

:end 

这样用批处理就方便多了。

   然后对于配置windows路由也说下吧：

具体用法    自己     route     help   查看吧。

route   print          ----查看路由条目

route   -p  add   0.0.0.0  mask  0.0.0.0    192.168.2.1        永久添加默认路由条目（默认metric值为1）

如果你有两个默认路由，可以设置metric  值，值越小，优先级越高，如果我有第二个默认路由：

route -p   add   0.0.0.0  mask   0.0.0.0    172.18.1.1   metric   2

route  delete  0.0.0.0               ----删除所有默认条目

route  delete  0.0.0.0  mask  0.0.0.0   172.18.1.1    --------------删除特定默认路由条目

技术博客提供给朋友们参考，如有错误、不足之处，或有不明白的地方，还请指出与追问。

联系邮箱：qrcg92@foxmail.com