您的位置:首页 > 其它

Flex应用的初始化顺序

2013-08-15 13:53 288 查看
最初的需求是需要在应用初始化的适当时机加载相关的配置信息,以便进行后续的初始化工作。后端是使用BlazeDS,整个系统基于RemoteObject通信。

Flex应用的初始化顺序是,preloader->systemManager->FlexApplication started…

然后才是:

preinitialize

  在所有的初始化之前触发,没有子组件的定义,但是可以引用组件的变量.

initialize

  当所有子组件生成完成后触发,在这个时间点还没有组件被渲染出来.

creationComplete

  组件定义完成并已经在显示列表.

applicationComplete

  所有的组件初始化完成并显示.

preinitialize之后application的初始化已经无法被控制了,所以需要在preinitialize之前进行配置信息的载入Preloader恰好能达到目的,通过重写SparkDownloadProgressBar,并监听FlexEvent.PRELOADER_DOC_FRAME_READY事件可以在application初始化前拦截。
override public function set preloader(value:Sprite):void
{
	super.preloader = value;
	_preloader = value;
 
	//在app初始化之前拦截
	value.addEventListener(FlexEvent.PRELOADER_DOC_FRAME_READY,applicationInit,false,int.MAX_VALUE);
}
 
/**
 * 加载权限配置等信息
 * */
private function applicationInit(event:FlexEvent):void{
	//暂停app初始化
	event.stopImmediatePropagation();
	suspend = true;
 
	var con:NetConnection = new NetConnection();
	con.objectEncoding = ObjectEncoding.AMF3
	con.connect("./messagebroker/amf");
 
	con.addEventListener(NetStatusEvent.NET_STATUS, function():void{});
	con.addEventListener(SecurityErrorEvent.SECURITY_ERROR, function():void{});
	con.addEventListener(IOErrorEvent.IO_ERROR, function():void{});
	con.addEventListener(AsyncErrorEvent.ASYNC_ERROR, function():void{});
 
	con.call("systemFlex.getUserInfo",new Responder(sysInitHandler,faultHandler));
 
}
 
/**
 * 配置信息载入处理,与初始化信息设置
 * */
private function sysInitHandler(data:Object):void{
 
	//如果加载到信息
	if(data.uid){
		//进行用户信息初始化
 
		var model:GlobalModel = GlobalModel.getInstance();
		model.uid = data.uid;
		model.username = data.username;
 
		if(data.privileges){
			var privileges:XMLList = new XMLList(data.privileges);
			//权限树
			model.privileges = privileges;
 
			//由于进入此方法时flex资源还未加载完成,ArrayCollection无法使用,所以把权限控制放到app的preinitialize初始化
			//var privilegesArr:ArrayCollection = new ArrayCollection(privileges..node.@id.toXMLString().split("\n"));
 
			//msgBox.text = "启动权限控制...";
			//启动权限控制
			//SecurityControler.start(privilegesArr);
 
			msgBox.text = "初始化用户信息完成.";
 
			_preloader.removeEventListener(FlexEvent.PRELOADER_DOC_FRAME_READY,applicationInit);
			suspend = false;
			//重新发起事件,继续app初始化
			_preloader.dispatchEvent(new FlexEvent(FlexEvent.PRELOADER_DOC_FRAME_READY));
 
		}else{
			msgBox.text = "权限信息加载失败,初始化终止!";
		}
	}else{
		msgBox.text = "加载初始化信息错误,初始化终止!";
	}
}
 
private function faultHandler(info:Object):void{
	msgBox.text = "加载系统和用户配置信息失败,初始化终止!\n"+info.message;
}
通过FlexEvent.PRELOADER_DOC_FRAME_READY事件可以达到代码在application初始化前执行。但由于此时应用还没有完全载入,许多mx,spark组件都不能正常使用所以需要用flash包下提供的类和方法来达到目的。

  最初我使用RemoteObject去加载数据但由于ResourceManager还没有完全初始化完成,导致报错。并且诸如ArrayCollection这样位于mx或spark包下的数据类型也是无法使用的,所以在以对象的形式进行数据传输时要避免数据被转换为这些类型。在项目中由于需要进行UI的权限控制使用了一个叫FlexSecurity的框架由于其初始化需要使用的ArrayCollection在监听代码中还无法使用,在不影响功能的前提下变通的把权限的初始化转移到application的preinitialize进行。
内容来自用户分享和网络整理,不保证内容的准确性,如有侵权内容,可联系管理员处理 点击这里给我发消息
标签: