用dos命令行导出和导出windows计划任务的详解
2012-11-20 17:12
309 查看
声明:博客内所有技术性文章都是由作者本人工作经验的总结, 实现过程中有搜索资料为参考的绝不涉嫌抄袭,均为个人习惯的总结。
今天要把公司软件用的计划任务用命令行批处理的方式导入一个新的系统里,所有通过查资料,写出来一个可以用来导出和导入的脚本,用法为:脚本名称+空格+export和脚本名称+空格+import,以下为内容和注释:
rem 以下为关闭命令打印
@echo off
rem 以下为清屏
cls
rem 以下为设置此批处理所有的环境变量只应用于当前批处理
setlocal EnableDelayedExpansion
rem 以下为设置变量
set runasUsername=domain\administrator
set runasPassword=password
rem 以下%1是在此批处理执行时后面的第一个命令行参数(在执行的格式:脚本名+export 就相当于跳转到”:export“)
if %1. == export. call :export
if %1. == import. call :import
rem 以下为退出当前脚本,不是退出整个批处理
exit /b 0
:export
rem 以下为创建一个tasks文件夹,所有的错误不显示
md tasks 2>nul
rem 以下为列出所有计划任务并指定csv格式,然后找出与字符串TaskName不匹配的行,输出到一个文本文件
schtasks /query /fo csv | findstr /V /c:"TaskName" > tnlist.txt
rem 循环查找以(,)为分隔符列出每一行的每一项,指定%%i为第一项,用tokens=1,2指定第二项%%j和第三项%%k(也可以
rem 指定%%t为第一项,那么tokens=1,2指定第二项%%u和第三项%%v,第四项为%%W)
for /F "delims=, tokens=1,2*" %%i in (tnlist.txt) do (
echo %%i
echo %%j
echo %%k
set tn=%%i
rem 以下为设置fn为把tn的内容里的\替换成#
set fn=!tn:\=#!
echo !tn!
echo !fn!
rem 以下为列出所有计划任务并指定xml格式,输出到当前目录的tasks文件夹下的XXX.xml文件
schtasks /query /xml /TN !tn! > tasks\!fn!.xml
)
rem 删除所有windows自带的计划任务
del tasks\#Microsoft*.xml
exit /b 0
rem 以下为导入标签,在执行的格式:脚本名+import 将会直接跳转到这里开始执行
:import
rem 在这个目录里循环找到所有的xml
for %%f in (tasks\*.xml) do (
rem 用call命令来调用(:importfile)标签执行,并赋予上面查找出来的名字为参数
call :importfile "%%f"
)
exit /b 0
:importfile
rem 以下为设置filename=上面用call命令调用时赋予的第一个参数,如果是 set filename=%2则是第二个参数
set filename=%1
rem 以下为设置把filename里#字符替换为空
set taskname=%filename:#=%
rem 以下为设置把filename里tasks\字符替换为空
set taskname=%taskname:tasks\=%
rem 以下为设置把filename里.xml字符替换为空
set taskname=%taskname:.xml=%
rem 以下为用用户名和密码创建名字为XXX的计划认为,以xml文件为参数
schtasks /create /ru %runasUsername% /rp %runasPassword% /tn %taskname% /xml %filename%
echo on
结束,这样就可以导出所有不是系统自带的计划任务和导入现有的xml格式的计划任务了
最近工作中发现Win2008R2系统中的计划任务可以从系统目录中拷贝出来直接使用,只要自己把扩展名修改成 xml 就可以手动或是使用上面的脚本的再次导入。
QQ 交流 群 221046788
今天要把公司软件用的计划任务用命令行批处理的方式导入一个新的系统里,所有通过查资料,写出来一个可以用来导出和导入的脚本,用法为:脚本名称+空格+export和脚本名称+空格+import,以下为内容和注释:
rem 以下为关闭命令打印
@echo off
rem 以下为清屏
cls
rem 以下为设置此批处理所有的环境变量只应用于当前批处理
setlocal EnableDelayedExpansion
rem 以下为设置变量
set runasUsername=domain\administrator
set runasPassword=password
rem 以下%1是在此批处理执行时后面的第一个命令行参数(在执行的格式:脚本名+export 就相当于跳转到”:export“)
if %1. == export. call :export
if %1. == import. call :import
rem 以下为退出当前脚本,不是退出整个批处理
exit /b 0
:export
rem 以下为创建一个tasks文件夹,所有的错误不显示
md tasks 2>nul
rem 以下为列出所有计划任务并指定csv格式,然后找出与字符串TaskName不匹配的行,输出到一个文本文件
schtasks /query /fo csv | findstr /V /c:"TaskName" > tnlist.txt
rem 循环查找以(,)为分隔符列出每一行的每一项,指定%%i为第一项,用tokens=1,2指定第二项%%j和第三项%%k(也可以
rem 指定%%t为第一项,那么tokens=1,2指定第二项%%u和第三项%%v,第四项为%%W)
for /F "delims=, tokens=1,2*" %%i in (tnlist.txt) do (
echo %%i
echo %%j
echo %%k
set tn=%%i
rem 以下为设置fn为把tn的内容里的\替换成#
set fn=!tn:\=#!
echo !tn!
echo !fn!
rem 以下为列出所有计划任务并指定xml格式,输出到当前目录的tasks文件夹下的XXX.xml文件
schtasks /query /xml /TN !tn! > tasks\!fn!.xml
)
rem 删除所有windows自带的计划任务
del tasks\#Microsoft*.xml
exit /b 0
rem 以下为导入标签,在执行的格式:脚本名+import 将会直接跳转到这里开始执行
:import
rem 在这个目录里循环找到所有的xml
for %%f in (tasks\*.xml) do (
rem 用call命令来调用(:importfile)标签执行,并赋予上面查找出来的名字为参数
call :importfile "%%f"
)
exit /b 0
:importfile
rem 以下为设置filename=上面用call命令调用时赋予的第一个参数,如果是 set filename=%2则是第二个参数
set filename=%1
rem 以下为设置把filename里#字符替换为空
set taskname=%filename:#=%
rem 以下为设置把filename里tasks\字符替换为空
set taskname=%taskname:tasks\=%
rem 以下为设置把filename里.xml字符替换为空
set taskname=%taskname:.xml=%
rem 以下为用用户名和密码创建名字为XXX的计划认为,以xml文件为参数
schtasks /create /ru %runasUsername% /rp %runasPassword% /tn %taskname% /xml %filename%
echo on
结束,这样就可以导出所有不是系统自带的计划任务和导入现有的xml格式的计划任务了
最近工作中发现Win2008R2系统中的计划任务可以从系统目录中拷贝出来直接使用,只要自己把扩展名修改成 xml 就可以手动或是使用上面的脚本的再次导入。
QQ 交流 群 221046788
相关文章推荐
- 用dos命令实现导入、导出windows计划任务详解
- DOS命令行操作计划任务详解
- 如何用命令行操作Windows Scheduled Task (计划任务)?
- 解决,windows的任务计划中添加一个批处理脚本,总是显示命令行窗口的问题
- 详解 如何在 windows 7添加启动项 ,强大的计划任务功能 推荐
- Windows命令行创建计划任务
- windows命令行(DOS批处理)添加任务计划
- Windows导出所有计划任务方法
- 批量导入导出windows计划任务的批处理脚本
- 详解Windows和Linux下从数据库导出表结构,以及Linux下如何导入.sql文件到MySQL数据库
- 通过windows计划任务和Dos批处理备份文件
- windows任务计划和批处理脚本结合完成的一些简单功能
- 脚步创建windows计划任务
- DOS命令创建以日期为文件名的任务计划TXT文件
- Windows下Spring3.x计划任务实现定时备份MySql数据库
- Asp.net(C#) windows 服务{用于实现计划任务,事件监控等}
- windows命令行中java和javac、javap使用详解(java编译命令)
- 利用windows的计划任务制作一个定时执行的清理端口任务
- [计划任务 - dos]制作任务工具
- windows计划任务PHP