Configuration files for TCP/IP boot disk

Autoexec.bat :
@ECHO OFF

SET CDDRIVE=X

path=a:\;

SET COMSPEC=A:\COMMAND.COM

IF %CONFIG%==NORM GOTO detect_scsi

SET NETCARD=%CONFIG%

:detect_scsi

choice /c:yn /t:n,3 Carte SCSI ?

IF NOT ERRORLEVEL==2 goto scsi

REM load a standard IDE CD drive
DEVLOAD CPQIDECD.SYS /d:IDECD01

LH MSCDEX /l:X /d:IDECD01

goto suite

:scsi
REM attempt to load adaptect ISA SCSI board

ddloader aspi4dos.sys

REM uses Bart's PCISCAN to find which PCI scsi board we got
PCISCAN SCSI.MAP

ddloader %pci0%

choice /c:yn /t:n,2 Compaq SCSI board ?

IF ERRORLEVEL==2 goto aspicd

ddloader fw2aspi.sys

:aspicd

DEVLOAD ASPICD.SYS /d:SCSICD

LH MSCDEX /l:X /d:SCSICD

goto suite

:suite

SET CDDRIVE=X

:suite2

SET RAMDRIVE=r
REM load the famous ramdrive

XMSDSK 3000 r: /y

SET TEMP=%RAMDRIVE%:\

SET TMP=%RAMDRIVE%:\

path=%CDDRIVE%:\DOS;%CDDRIVE%:\NET;a:\;%CDDRIVE%:\NETUTILS

SET COMSPEC=%CDDRIVE%:\DOS\

LH KEYB FR

REM call an optional batch file (could be added with a new CD session)
IF EXIST %CDDRIVE%:\LANCE.BAT CALL %CDDRIVE%:\LANCE.BAT

IF "%CONFIG%"=="NORM" goto suite3

%CDDRIVE%:

cd net

ECHO to configure your network files type in : NETCFG

:suite3

:FIN

Config.SYS :
[MENU]

menuitem=NORM, No Network
submenu=menu_res, Network boot menu

[menu_res]

menuitem=AUTO , Attempt to auto-detect a PCI network adapter !!!

menuitem=5X9 , 3com ISA Etherlink III 3C5X9

menuitem=NE2000 , NE2000 ISA

submenu=menu_pci, PCI NICs

submenu=menu_pcmcia, PCMCIA NICs

submenu=menu_tok, Token-Ring NICs

[menu_tok]

menuitem=OLITOK , PCMCIA Olicom 3221

menuitem=PRESTO , Madge Presto

[menu_pci]

menuitem=59X , 3C59X 10/100

menuitem=90X , Etherlink XL 10/100 3C905

menuitem=NFLX , Compaq NetFlex 3

menuitem=E1B , INTEL E100B

menuitem=NE2PCI , NE2000 PCI

[menu_pcmcia]

menuitem=CBEM , Xircom CBEM CardBus (10/100)

menuitem=CEM , Xircom CEM (10/100)

menuitem=OCE20 , Olicom 20
menuitem=OCE4X , Olicom 4x

[COMMON]

shell=a:\command.com /p

DOS=HIGH,UMB

files=30

lastdrive=z

[NORM]

[AUTO]

[OCE4X]

DEVICEHIGH=A:\OCTENABL.DOS IA=10

[OCE20]

DEVICEHIGH=A:\OCTENABL.DOS IA=10

[E1B]

[NFLX]

[PRESTO]

[CBEM]

[CEM]

[OLITOK]

DEVICEHIGH=A:\OCTENABL.DOS IA=10

[NE2000]

[NE2PCI]

[5X9]

[59X]

[90X]

[COMMON]

device=a:\ifshlp.sys

DEVICE=A:\HIMEM.SYS /testmem:off

device=a:\emm386.exe NOEMS X=D000-D300

NETCFG.BAT
@ECHO OFF

REM we are in the destination NET directory on the ramdrive

r:

cd \

md net

cd net
REM Copy of all net files to the ramdrive (need r/w access)

%CDDRIVE%:\DOS\xcopy /S %CDDRIVE%:\NET .

copy protocol.sam protocol.ini

REM change settings according to the ramdrive letter

ini system.ini WRITE "network" lanroot %RAMDRIVE%:\NET

ini system.ini WRITE "network drivers" devdir %RAMDRIVE%:\NET

REM launch autodetec of PCI devices
IF "%NETCARD%"=="AUTO" %CDDRIVE%:\DOS\PCISCAN %CDDRIVE%:\DOS\NIC.MAP

SET NETCARD=%PCI0%

IF ERRORLEVEL== 1 goto _nodetect

REM change settings according to the chosen/detected board
IF "%NETCARD%"=="59X" ini system.ini WRITE "network drivers" netcard EL59X.DOS

IF "%NETCARD%"=="59X" ini Protocol.ini WRITE CARTE drivername EL59X$

IF "%NETCARD%"=="90X" ini system.ini WRITE "network drivers" netcard EL90X.DOS

IF "%NETCARD%"=="90X" ini Protocol.ini WRITE CARTE drivername EL90X$

IF "%NETCARD%"=="5X9" ini system.ini WRITE "network drivers" netcard elnk3.dos

IF "%NETCARD%"=="5X9" ini Protocol.ini WRITE CARTE drivername ELNK3$

IF "%NETCARD%"=="E1B" ini system.ini WRITE "network drivers" netcard e100b.dos

IF "%NETCARD%"=="E1B" ini Protocol.ini WRITE CARTE drivername E100B$

IF "%NETCARD%"=="E1B" ini Protocol.ini WRITE CARTE FORCEDUPLEX 1

IF "%NETCARD%"=="CBEM" ini system.ini WRITE "network drivers" netcard CBENDIS.exe

IF "%NETCARD%"=="CBEM" ini Protocol.ini WRITE CARTE drivername XIRCOM$

IF "%NETCARD%"=="CBEM" ini Protocol.ini WRITE CARTE IRQ 15

IF "%NETCARD%"=="CBEM" ini Protocol.ini WRITE CARTE MODE IO

IF "%NETCARD%"=="CBEM" ini Protocol.ini WRITE CARTE LINEMODE HALF

IF "%NETCARD%"=="CEM" ini system.ini WRITE "network drivers" netcard XCEMNDIS.EXE

IF "%NETCARD%"=="CEM" ini Protocol.ini WRITE CARTE drivername XIRCOM$

IF "%NETCARD%"=="CEM" ini Protocol.ini WRITE CARTE LINEMODE HALF

IF "%NETCARD%"=="NE2000" ini system.ini WRITE "network drivers" netcard NE2000.DOS

IF "%NETCARD%"=="NE2000" ini Protocol.ini WRITE CARTE drivername MS2000$

IF "%NETCARD%"=="NE2PCI" ini system.ini WRITE "network drivers" netcard PCIND.DOS

IF "%NETCARD%"=="NE2PCI" ini Protocol.ini WRITE CARTE drivername PCIND$

IF "%NETCARD%"=="NFLX" ini system.ini WRITE "network drivers" netcard netflx3.dos

IF "%NETCARD%"=="NFLX" ini Protocol.ini WRITE CARTE drivername NTFLX3$

IF "%NETCARD%"=="NFLX" ini Protocol.ini WRITE CARTE DUPLEX HALF

IF "%NETCARD%"=="OCE20" ini system.ini WRITE "network drivers" netcard Oce20nd2.dos

IF "%NETCARD%"=="OCE20" ini Protocol.ini WRITE CARTE drivername OCE20$

IF "%NETCARD%"=="OCE4X" ini system.ini WRITE "network drivers" netcard Oce4xnd2.dos

IF "%NETCARD%"=="OCE4X" ini Protocol.ini WRITE CARTE drivername OCE4X$

IF "%NETCARD%"=="OLITOK" ini system.ini WRITE "network drivers" netcard olitok16.dos

IF "%NETCARD%"=="OLITOK" ini Protocol.ini WRITE CARTE drivername OLITOK$

IF "%NETCARD%"=="PRESTO" ini system.ini WRITE "network drivers" netcard mdgnd.dos

IF "%NETCARD%"=="PRESTO" ini Protocol.ini WRITE CARTE drivername MDGND$

choice /c:on /t:n,1 "Force 100 Mb Full Duplex ? "

if errorlevel==2 goto askprot
REM change settings depending on the board

IF "%NETCARD%"=="CBEM" ini Protocol.ini WRITE CARTE LINESPEED 100

IF "%NETCARD%"=="CBEM" ini Protocol.ini WRITE CARTE LINEMODE FULL

IF "%NETCARD%"=="CEM" ini Protocol.ini WRITE CARTE LINESPEED 100

IF "%NETCARD%"=="CEM" ini Protocol.ini WRITE CARTE LINEMODE FULL

IF "%NETCARD%"=="NFLX" ini Protocol.ini WRITE CARTE MEDIASPEED 100

IF "%NETCARD%"=="NFLX" ini Protocol.ini WRITE CARTE DUPLEX FULL

IF "%NETCARD%"=="E1B" ini Protocol.ini WRITE CARTE SPEED 100

IF "%NETCARD%"=="E1B" ini Protocol.ini WRITE CARTE FORCEDUPLEX 2

IF "%NETCARD%"=="5X9" %CDDRIVE%:\NETUTILS\3c59Xcfg CONFIGURE /TR:100BASE-T /FULLDUPLEX:ENABLE

:askprot

choice /c:on /t:o,3 "TCP/IP ? "

if not errorlevel==2 goto askdhcp

REM if no tcp/ip , go load netbeui
set proto=netbeui

ini system.ini WRITE "network drivers" transport "ndishlp.sys,*netbeui"

goto suite

:askdhcp

set proto=tcpip

ini system.ini WRITE "network drivers" transport "dis_pkt.dos,tcpdrv.dos,nemm.dos"

choice /c:on /t:o,3 "Do you want to get an address with DHCP ? "

if NOT errorlevel==2 goto dhcp

GET S "Enter the IP address (dotted-separated : 10.1.1.1):"

echo IP=%GET% > WATTCP.CFG

GET S "Subnet mask :"

echo NETMASK=%GET% >> WATTCP.CFG

GET S "Default gateway"

echo GATEWAY=%GET% >> WATTCP.CFG
REM WATTCP.cfg is used by the IP layer of both Ghost and DriveImage

REM remove dots from wattcp.cfg and write VARS.VAR
TYPE WATTCP.CFG | TR "." " " > VARS.VAR

REM use EDITENV to load these vars

EDITENV @VARS.VAR
REM and write them in protocol.ini

ini Protocol.ini WRITE tcpip IPAddress0 "%IP%"

ini Protocol.ini WRITE tcpip SubNetMask0 "%NETMASK%"

ini Protocol.ini WRITE tcpip DefaultGateway0 "%GATEWAY%"

ini Protocol.ini WRITE tcpip DisableDHCP 1

goto suite

:dhcp

ini Protocol.ini WRITE tcpip DisableDHCP 0

echo IP=0.0.0.0 > WATTCP.CFG

:suite

ini system.ini WRITE network preferredredir Full

ini system.ini WRITE network autostart Full

choice /c:yn /t:n,2 "Full Redirector ? "
REM the Full redirector uses much more memory

IF NOT ERRORLEVEL==2 goto choicdom

ini system.ini WRITE network preferredredir basic

ini system.ini WRITE network autostart basic

:choicdom

choice /c:on /t:n,3 "Use a specific logon domain name ? "

IF ERRORLEVEL==2 goto fin

GET S "Enter logon domain name :"

ini system.ini WRITE network logondomain %GET%

goto fin

_nodetect:

ECHO autodetect has failed edit protocol.ini and system.ini yourself
%CDDRIVE%\DOS\PCISCAN -v

goto finfin

:fin

ECHO you still can edit system.ini and protocol.ini yourself

ECHO to start the network use NETSTART

:finfin

NETSTART.BAT

path=%PATH%;x:\net

if "%1%"=="" goto net

:net

if %proto%==netbeui goto init

net start netbind

umb.com

tcptsr.exe

tinyrfc.exe

nmtsr.exe

emsbfr.exe

:init

net initialize

net start

:fin

Protocol.ini

; This is a template for a multi protocol configurable net adapter

[network.setup]

version=0x3110
; CARTE is a placeholder

netcard=CARTE,1,CARTE,1

; prepare for binding both protocols
transport=tcpip,TCPIP

transport=netbeui,netbeui

lana0=CARTE,1,tcpip

lana1=CARTE,1,netbeui

[CARTE]

; here goes your driver id (usually ends with '$')

drivername=<TO_BE_EDITED_BY_NETCFG.BAT>

[PKTDRV]
; packet driver for Ghost and DriveImage IP layer

drivername = PKTDRV$

bindings = CARTE

intvec = 0x60

chainvec = 0x66

[protman]

drivername=PROTMAN$

PRIORITY=NDISHLP

[netbeui]

drivername=netbeui$

BINDINGS=CARTE

LANABASE=1

[ndishlp]

drivername=ndishlp$

BINDINGS=CARTE

LANABASE=0

[tcpip]
; IP Parameters

NBSessions=6

DefaultGateway0=
; ex : 255 255 255 0

SubNetMask0=<TO_BE_EDITED_BY_NETCFG.BAT>
; ex : 10 1 1 1

IPAddress0=<TO_BE_EDITED_BY_NETCFG.BAT>
; ex : 0 or 1
DisableDHCP=<TO_BE_EDITED_BY_NETCFG.BAT>

DriverName=TCPIP$

BINDINGS=CARTE

LANABASE=0

System.ini
; This is a template for a multi protocol configurable net adapter

[network]

filesharing=no

printsharing=no

autologon=yes

ComputerName=0

; usually R:\NET
lanroot=<TO_BE_EDITED_BY_NETCFG.BAT>

username=

workgroup=

reconnect=no

dospophotkey=N

lmlogon=0

logondomain=<TO_BE_EDITED_BY_NETCFG.BAT>
; default would be basic

preferredredir=<TO_BE_EDITED_BY_NETCFG.BAT>
; default would be basic

autostart=<TO_BE_EDITED_BY_NETCFG.BAT>

maxconnections=8

[network drivers]

; transport is "ndishlp.sys,*netbeui" for netbeui and "dis_pkt.dos,tcpdrv.dos,nemm.dos" for tcp/ip

transport=<TO_BE_EDITED_BY_NETCFG.BAT>

; usually "R:\NET"

devdir=<TO_BE_EDITED_BY_NETCFG.BAT>

LoadRMDrivers=yes
; netcard is the file for the nic driver (elnk3.dos or CBEM.EXE ...)

netcard=<TO_BE_EDITED_BY_NETCFG.BAT>

[Password Lists]