批处理添加桌面快捷方式

::██████████████████████{创建Internet快捷方式}███████████████████████
@Echo off
echo [InternetShortcut] >"%userprofile%\桌面\百度.url"
echo URL=http://www.baidu.com >>"%userprofile%\桌面\百度.url"
echo IconIndex=0 >>"%userprofile%\桌面\百度.url"
echo IconFile=C:\WINDOWS\system32\url.dll >>"%userprofile%\桌面\百度.url"

::██████████████████████{创建文件的快捷方式}████████████████████████

███方法一：批处理创建快捷方式并指定快捷键★★★★★
@Echo off
>%temp%\a.vbs echo Set AAA = WScript.CreateObject("WScript.Shell") '设置CreateObject 方法
>>%temp%\a.vbs echo set BBB = AAA.CreateShortcut("%userprofile%\桌面\服务.lnk") '设置快捷方式的路径和名称
>>%temp%\a.vbs echo BBB.TargetPath = "C:\WINDOWS\system32\services.msc" '快捷方式里的“目标”
>>%temp%\a.vbs echo BBB.Arguments = "/s" '参数
>>%temp%\a.vbs echo BBB.WindowStyle = 1 '快捷方式里的“运行方式”，1为常规窗口、2为最小化、3为最大化
>>%temp%\a.vbs echo BBB.Hotkey = "CTRL+ALT+J" '快捷方式里的“快捷键”
>>%temp%\a.vbs echo BBB.IconLocation = "C:\WINDOWS\NOTEPAD.EXE,0" '快捷方式的图标
>>%temp%\a.vbs echo BBB.Description = "" '快捷方式里的“备注”
>>%temp%\a.vbs echo BBB.WorkingDirectory = "C:\WINDOWS\" '快捷方式里的“起始位置”
>>%temp%\a.vbs echo BBB.Save '建立快捷方式
%temp%\a.vbs
█方法二：调用winrar
此方法的缺点是后面不能跟参数
@Echo off
echo Path=%%SystemRoot%%\system32\ >%temp%\a.txt
echo Silent=^1 >>%temp%\a.txt
echo Overwrite=^1 >>%temp%\a.txt
echo Shortcut=D, "mspaint.exe", "\", "创建和编辑图画，以及显示和编辑扫描获得的图片。", "图画" >>%temp%\a.txt
start /wait winrar.exe a -r -ep1 -m1 -sfx -z"%temp%\a.txt" %temp%\a.exe %SystemRoot%\system32\mspaint.exe
start /wait %temp%\a.exe
del %temp%\a.*
解释：此方法是先将指定文件打包成rar自解压文件，再利用rar自解压的功能来创建快捷方式的。