Uboot 源码分析----启动代码

bootloader中start.S详细注解

@文件包含处理


#include <config.h>

@由顶层的mkconfig生成，其中只包含了一个文件：configs/<顶层makefile中6个参数的第1个参数>.h


#include <version.h>

#include <status_led.h>

/*

*************************************************************************

*

* Jump vector table as in table 3.1 in [1]

*

*************************************************************************

*/

@向量跳转表，每条占一字节，地址范围为0x0000 0000～0x0000 0020

@ARM体系结构规定在上电复位后的起始位置，必须有8条连续的跳转指令，通过硬件实现。他们就是异常向量表。ARM在上电复位后，是从
0x00000000开始启动的，其实如果bootloader存在，在执行下面第一条指令后，就无条件跳转到start_code，下面一部分并没执
行。设置异常向量表的作用是识别bootloader。以后系统每当有异常出现，则CPU会根据异常号，从内存的0x00000000处开始查表做相应的
处理


.globl _start

@_start是GNU汇编器的默认入口标签，.globl将_start声明为外部程序可访问的标签，.globl是GNU汇编的保留关键字，前面加点是GNU汇编的语法

_start: b start_code @0x00

@ARM上电后执行的第一条指令，也即复位向量，跳转到start_code

ldr pc, _undefined_instruction @0x04

ldr pc, _software_interrupt @0x08

ldr pc, _prefetch_abort @0x0c

ldr pc, _data_abort @0x10

ldr pc, _not_used @0x14

ldr pc, _irq @0x18

ldr pc, _fiq @0x1c

@对于ARM数据从内存到CPU之间的移动只能通过L/S指令，如：ldr
r0,0x12345678为把0x12345678内存中的数据写到r0中，还有一个就是ldr伪指令，如：ldr
r0,=0x12345678为把0x12345678地址写到r0中，mov只能完成寄存器间数据的移动，而且立即数长度限制在8位

_undefined_instruction: .word undefined_instruction

_software_interrupt: .word software_interrupt

_prefetch_abort: .word prefetch_abort

_data_abort: .word data_abort

_not_used: .word not_used

_irq: .word irq

_fiq: .word fiq

@.word为GNU ARM汇编特有的伪操作，为分配一段字内存单元（分配的单元为字对齐的），可以使用.word把标志符作为常量使用。如_fiq:.word fiq即把fiq存入内存变量_fiq中，也即是把fiq放到地址_fiq中。


.balignl 16,0xdeadbeef

@.balignl是.balign的变体，为伪操作符，控制对齐方式。它的意思是以当前地址开始，地址计数器必须是以第一个参数为整数倍的地址为尾，在
前面记录一个长字长度的信息，信息为第二个参数。【参考好野人的窝，于关u-boot中的.balignl 16,0xdeadbeef的理解 http://haoyeren.blog.sohu.com/84511571.html
】

/*

*************************************************************************

*

* Startup Code (called from the ARM reset exception vector)

*

* do important init only if we don't start from memory!

* relocate armboot to ram

* setup stack

* jump to second stage

*

*************************************************************************

*/

@代码数据地址的初始化


_TEXT_BASE:

.word TEXT_BASE

@TEXT_BASE在开发板相关的目录中的config.mk文档中定义, 他定义了代码在运行时所在的地址, 那么_TEXT_BASE中保存了这个地址（这个TEXT_BASE是编译的时候从编译选项的宏定义传进来的。）


.globl _armboot_start

_armboot_start:

.word _start

@用_start来初始化_armboot_start。（就是为了定义一个地址而已，用作后面stack setup之用）


/*

* These are defined in the board-specific linker script.

*/

@下面这些是定义在开发板目录链接脚本中的


.globl _bss_start

_bss_start:

.word __bss_start

@__bss_start定义在和开发板相关的u-boot.lds中，_bss_start保存的是__bss_start标号所在的地址。


.globl _bss_end

_bss_end:

.word _end

@同上，这样赋值是因为代码所在地址非编译时的地址，直接取得该标号对应地址。


@中断的堆栈设置


#ifdef CONFIG_USE_IRQ

/* IRQ stack memory (calculated at run-time) */

.globl IRQ_STACK_START

IRQ_STACK_START:

.word 0x0badc0de

/* IRQ stack memory (calculated at run-time) */

.globl FIQ_STACK_START

FIQ_STACK_START:

.word 0x0badc0de

#endif


/*

* the actual start code

*/

@复位后从复位向量哪里跳转过来的。

@真正的初始化从这里开始了。

@当然这里是片外启动模式。

@对于at91rm9200 uboot 有两种执行模式。（其实在amtel中只是定义第一种，后面一种是大多数其他板子的设定）
@ 第一种是 boot.bin + uboot.gz 存放在FLASH中
@ 在这种情况下，加电的时候执行的是boot.bin的代码，boot.bin除了初始化板上的基本硬件设备之外，最主要的功能是将uboot.gz的代码解压到_TEXT_BASE指定的地方，也就是第一片@ SDRAM的地方。然后跳转到uboot中代码中去执行。也就是start所在的代码。
@ 第二种是uboot.bin存放在FLASH中，这样加电启动的时候，执行的就是这里的代码。

start_code:

/*

* set the cpu to SVC32 mode

*/

@更改处理器模式为管理模式

@对状态寄存器的修改要按照：读出-修改-写回的顺序来执行

@

31 30 29 28 --- 7 6 - 4 3 2 1 0

N Z C V I F M4 M3 M2 M1 M0

0 0 0 0 0 User26 模式

0 0 0 0 1 FIQ26 模式

0 0 0 1 0 IRQ26 模式

0 0 0 1 1 SVC26 模式

1 0 0 0 0 User 模式

1 0 0 0 1 FIQ 模式

1 0 0 1 0 IRQ 模式

1 0 0 1 1 SVC 模式

1 0 1 1 1 ABT 模式

1 1 0 1 1 UND 模式

1 1 1 1 1 SYS 模式


mrs r0,cpsr

@将cpsr的值读到r0中

bic r0,r0,#0x1f

@清除M0~M4

orr r0,r0,#0xd3

@禁止IRQ,FIQ中断，并将处理器置于管理模式

msr cpsr,r0

@以下是点灯了，这个是lib_arm定义的接口，具体的板子如果需要，可以定义相关实现内容
。具体实现方法是#include <common.h>

bl coloured_LED_init

bl red_LED_on

@针对AT91RM9200进行特殊处理

#if defined(CONFIG_AT91RM9200DK) || defined(CONFIG_AT91RM9200EK)

/*

* relocate exception table，因为是atmel定义的是第一种模式所以uboot.bin的代码是从flash中解压出来的，所以当解压到sdram的时候还要将向量表拷贝到flash中。

*/

ldr r0, =_start

ldr r1, =0x0

mov r2, #16

copyex:

subs r2, r2, #1

@sub带上了s用来更改进位标志，对于sub来说，若发生借位则C标志置0，没有则为1，这跟adds指令相反！要注意。

ldr r3, [r0], #4

str r3, [r1], #4

bne copyex

#endif

@针对S3C2400和S3C2410进行特殊处理

@CONFIG_S3C2400、CONFIG_S3C2410等定义在include/configs/下不同开发板的头文件中

#if defined(CONFIG_S3C2400) || defined(CONFIG_S3C2410)

/* turn off the watchdog */

@关闭看门狗定时器的自动复位功能并屏蔽所有中断，上电后看门狗为开，中断为关

# if defined(CONFIG_S3C2400)

# define pWTCON 0x15300000

# define INTMSK 0x14400008 /* Interupt-Controller base addresses */

# define CLKDIVN 0x14800014 /* clock divisor register */

#else @s3c2410的配置

# define pWTCON 0x53000000

@pWTCON定义为看门狗控制寄存器的地址（s3c2410和s3c2440相同）

# define INTMSK 0x4A000008 /* Interupt-Controller base addresses */

@INTMSK定义为主中断屏蔽寄存器的地址（s3c2410和s3c2440相同）

# define INTSUBMSK 0x4A00001C

@INTSUBMSK定义为副中断屏蔽寄存器的地址（s3c2410和s3c2440相同）

# define CLKDIVN 0x4C000014 /* clock divisor register */

@CLKDIVN定义为时钟分频控制寄存器的地址（s3c2410和s3c2440相同）

# endif

@至此寄存器地址设置完毕


ldr r0, =pWTCON

mov r1, #0x0

str r1, [r0]

@对于S3C2440和S3C2410的WTCON寄存器的[0]控制允许或禁止看门狗定时器的复位输出功能，设置为“0”禁止复位功能。


/*

* mask all IRQs by setting all bits in the INTMR - default

*/

mov r1, #0xffffffff

ldr r0, =INTMSK

str r1, [r0]

# if defined(CONFIG_S3C2410)

ldr r1, =0x3ff @2410好像应该为7ff才对（不理解uboot为何是这个数字）

ldr r0, =INTSUBMSK

str r1, [r0]

# endif

@对于S3C2410的INTMSK寄存器的32位和INTSUBMSK寄存器的低11位每一位对应一个中断，相应位置“1”为不响应相应的中断。对于S3C2440的INTSUBMSK有15位可用，所以应该为0x7fff了。


/* FCLK:HCLK:PCLK = 1:2:4 */

/* default FCLK is 120 MHz ! */

ldr r0, =CLKDIVN

mov r1, #3

str r1, [r0]

@时钟分频设置，FCLK为核心提供时钟，HCLK为AHB（ARM920T,内存控制器，中断控制
器，LCD控制器，DMA和主USB模块）提供时钟，PCLK为APB（看门狗、IIS、I2C、PWM、MMC、ADC、UART、GPIO、RTC、
SPI）提供时钟。分频数一般选择1：4：8，所以HDIVN=2,PDIVN=1，CLKDIVN=5，这里仅仅是配置了分频寄存器，关于
MPLLCON的配置肯定写在lowlevel_init.S中了哦。

@归纳出CLKDIVN的值跟分频的关系：

@0x0 = 1:1:1 , 0x1 = 1:1:2 , 0x2 = 1:2:2 , 0x3 = 1:2:4, 0x4 = 1:4:4, 0x5 = 1:4:8, 0x6 = 1:3:3,

0x7 = 1:3:6

@S3C2440的输出时钟计算式为:Mpll=(2*m*Fin)/(p*2^s)

S3C2410的输出时钟计算式为:Mpll=(m*Fin)/(p*2^s)

m=M(the value for divider M)+8;p=P(the value for divider P)+2

M,P,S的选择根据datasheet中PLL VALUE SELECTION TABLE表格进行，



我的开发板晶振为16.9344M，所以输出频率选为：399.65M的话M=0x6e,P=3,S=1

@s3c2440增加了摄像头,其FCLK、HCLK、PCLK的分频数还受到CAMDIVN[9]（默认为0）,CAMDIVN[8]（默认为0）的影响

#endif /* CONFIG_S3C2400 || CONFIG_S3C2410 */

/*

* we do sys-critical inits only at reboot,

* not when booting from ram!

*/

@选择是否初始化CPU

#ifndef CONFIG_SKIP_LOWLEVEL_INIT

bl cpu_init_crit

@执行CPU初始化，BL完成跳转的同时会把后面紧跟的一条指令地址保存到连接寄存器LR（R14）中。以使子程序执行完后正常返回。

#endif

@UBOOT将自己从FLASH中转移到RAM中

#ifndef CONFIG_SKIP_RELOCATE_UBOOT

relocate: /* relocate U-Boot to RAM */

adr r0, _start /* r0 <- current position of code */

ldr r1, _TEXT_BASE /* test if we run from flash or RAM */

cmp r0, r1 /* don't reloc during debug */

beq stack_setup

@通过比较_start和_TEXT_BASE值来确定uboot当前所在位置是否在内存中，若两值不同则表示在内存中运行，因为_start为uboot当前地址，_TEXT_BASE为连接时存放地址


ldr r2, _armboot_start

@_armboot_start为_start地址

ldr r3, _bss_start

@_bss_start为数据段地址

sub r2, r3, r2 /* r2 <- size of armboot */

add r2, r0, r2 /* r2 <- source end address */

copy_loop:

ldmia r0!, {r3-r10} /* copy from source address [r0] */

stmia r1!, {r3-r10} /* copy to target address [r1] */

@LDM(STM)用于在寄存器所指的一片连续存储器和寄存器列表的寄存器间进行数据移动，或是进行压栈和出栈操作。

格式为：LDM(STM){条件}{类型}基址寄存器{！}，寄存器列表{^}

对于类型有以下几种情况： IA 每次传送后地址加1，用于移动数据块

IB 每次传送前地址加1，用于移动数据块

DA 每次传送后地址减1，用于移动数据块

DB 每次传送前地址减1，用于移动数据块

FD 满递减堆栈，用于操作堆栈（即先移动指针再操作数据，相当于DB）

ED 空递减堆栈，用于操作堆栈（即先操作数据再移动指针，相当于DA）

FA 满递增堆栈，用于操作堆栈（即先移动指针再操作数据，相当于IB）

EA 空递增堆栈，用于操作堆栈（即先操作数据再移动指针，相当于IA）

（这里是不是应该要涉及到NAND或者NOR的读写？没有看出来）


cmp r0, r2 /* until source end addreee [r2] */

ble copy_loop

#endif /* CONFIG_SKIP_RELOCATE_UBOOT */

/* Set up the stack */

@初始化堆栈

stack_setup:

ldr r0, _TEXT_BASE /* upper 128 KiB: relocated uboot */

sub r0, r0, #CONFIG_SYS_MALLOC_LEN /* malloc area */

sub r0, r0, #CONFIG_SYS_GBL_DATA_SIZE /* bdinfo */

#ifdef CONFIG_USE_IRQ

sub r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)

#endif

sub sp, r0, #12 /* leave 3 words for abort-stack */

@初始化数据段

clear_bss:

ldr r0, _bss_start /* find start of bss segment */

ldr r1, _bss_end /* stop here */

mov r2, #0x00000000 /* clear */

clbss_l:str r2, [r0] /* clear loop... */

add r0, r0, #4

cmp r0, r1

ble clbss_l

@跳到阶段二C语言中去

ldr pc, _start_armboot

_start_armboot: .word start_armboot

@start_armboot在/lib_arm/中，到这里因该是第一阶段已经完成了吧，下面就要去C语言中执行第二阶段了吧

/*

*************************************************************************

*

* CPU_init_critical registers

*

* setup important registers

* setup memory timing

*

*************************************************************************

*/

@CPU初始化


#ifndef CONFIG_SKIP_LOWLEVEL_INIT

cpu_init_crit:

/*

* flush v4 I/D caches

*/

@初始化CACHES

mov r0, #0

mcr p15, 0, r0, c7, c7, 0 /* flush v3/v4 cache */

mcr p15, 0, r0, c8, c7, 0 /* flush v4 TLB */

/*

* disable MMU stuff and caches

*/

@关闭MMU和CACHES

mrc p15, 0, r0, c1, c0, 0

bic r0, r0, #0x00002300 @ clear bits 13, 9:8 (--V- --RS)

bic r0, r0, #0x00000087 @ clear bits 7, 2:0 (B--- -CAM)

orr r0, r0, #0x00000002 @ set bit 2 (A) Align

orr r0, r0, #0x00001000 @ set bit 12 (I) I-Cache

mcr p15, 0, r0, c1, c0, 0

@对协处理器的操作还是看不懂，暂时先不管吧，有时间研究一下ARM技术手册的协处理器部分。

/*

* before relocating, we have to setup RAM timing

* because memory timing is board-dependend, you will

* find a lowlevel_init.S in your board directory.

*/

@初始化RAM时钟，因为内存是跟开发板密切相关的，所以这部分在/开发板目录/lowlevel_init.S中实现

mov ip, lr

@保存LR,以便正常返回,注意前面是通过BL跳到cpu_init_crit来的。

@（ARM9有37个寄存器，ARM7有27个）

37个寄存器=7个未分组寄存器（R0～R7）+ 2×（5个分组寄存器R8～R12）+6×2（R13=SP，R14=lr 分组寄存器） + 1(R15=PC) +1(CPSR) + 5(SPSR)

用途和访问权限：

R0～R7:USR(用户模式)、fiq（快速中断模式）、irq（中断模式）、svc（超级用法模式）、abt、und

R8～R12：R8_usr～R12_usr（usr，irq，svc，abt，und）

R8_fiq～R12_fiq（fiq）

R11=fp

R12=IP(从反汇编上看，fp和ip一般用于存放SP的值)

R13～R14：R13_usr R14_usr(每种模式都有自己的寄存器)

SP ～lr ：R13_fiq R14_fiq

R13_irq R14_irq

R13_svc R14_svc

R13_abt R14_abt

R13_und R14_und

R15(PC)：都可以访问（即PC的值为当前指令的地址值加8个字节）

R16 ：（(Current Program Status Register，当前程序状态寄存器)）

SPSR _fiq,SPSR_irq,SPSR_abt,SPSR_und(USR模式没有)

#if defined(CONFIG_AT91RM9200EK)

#else

bl lowlevel_init

@跳到底层硬件初始化，这部分代码在自己建立的开发板目录下的lowlevel_init.S中。


#endif

mov lr, ip

mov pc, lr

@返回到主程序


#endif /* CONFIG_SKIP_LOWLEVEL_INIT */

/*

*************************************************************************

*

* Interrupt handling

*

*************************************************************************

*/

@异常处理的堆栈桢中的寄存器布局

@

@ IRQ stack frame.

@

#define S_FRAME_SIZE 72

#define S_OLD_R0 68

#define S_PSR 64

#define S_PC 60

#define S_LR 56

#define S_SP 52

#define S_IP 48

#define S_FP 44

#define S_R10 40

#define S_R9 36

#define S_R8 32

#define S_R7 28

#define S_R6 24

#define S_R5 20

#define S_R4 16

#define S_R3 12

#define S_R2 8

#define S_R1 4

#define S_R0 0

#define MODE_SVC 0x13

#define I_BIT 0x80

/*

* use bad_save_user_regs for abort/prefetch/undef/swi ...

* use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling

*/

.macro bad_save_user_regs

sub sp, sp, #S_FRAME_SIZE

stmia sp, {r0 - r12} @ Calling r0-r12

ldr r2, _armboot_start

sub r2, r2, #(CONFIG_STACKSIZE)

sub r2, r2, #(CONFIG_SYS_MALLOC_LEN)

sub r2, r2, #(CONFIG_SYS_GBL_DATA_SIZE+8) @ set base 2 words into abort stack

ldmia r2, {r2 - r3} @ get pc, cpsr

add r0, sp, #S_FRAME_SIZE @ restore sp_SVC

add r5, sp, #S_SP

mov r1, lr

stmia r5, {r0 - r3} @ save sp_SVC, lr_SVC, pc, cpsr

mov r0, sp

.endm

.macro irq_save_user_regs

sub sp, sp, #S_FRAME_SIZE

stmia sp, {r0 - r12} @ Calling r0-r12

add r7, sp, #S_PC

stmdb r7, {sp, lr}^ @ Calling SP, LR

str lr, [r7, #0] @ Save calling PC

mrs r6, spsr

str r6, [r7, #4] @ Save CPSR

str r0, [r7, #8] @ Save OLD_R0

mov r0, sp

.endm

.macro irq_restore_user_regs

ldmia sp, {r0 - lr}^ @ Calling r0 - lr

mov r0, r0

ldr lr, [sp, #S_PC] @ Get PC

add sp, sp, #S_FRAME_SIZE

subs pc, lr, #4 @ return & move spsr_svc into cpsr

.endm

.macro get_bad_stack

ldr r13, _armboot_start @ setup our mode stack

sub r13, r13, #(CONFIG_STACKSIZE)

sub r13, r13, #(CONFIG_SYS_MALLOC_LEN)

sub r13, r13, #(CONFIG_SYS_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack

str lr, [r13] @ save caller lr / spsr

mrs lr, spsr

str lr, [r13, #4]

mov r13, #MODE_SVC @ prepare SVC-Mode

@ msr spsr_c, r13

msr spsr, r13

mov lr, pc

movs pc, lr

.endm

.macro get_irq_stack @ setup IRQ stack

ldr sp, IRQ_STACK_START

.endm

.macro get_fiq_stack @ setup FIQ stack

ldr sp, FIQ_STACK_START

.endm

/*

* exception handlers

*/

@异常向量处理

@每一个异常向量处其实只放了一条跳转指令（因为每个异常向量只有4个字节不能放太多的程序），跳到相应的异常处理程序中。

.align 5

undefined_instruction:

get_bad_stack

bad_save_user_regs

bl do_undefined_instruction

.align 5

software_interrupt:

get_bad_stack

bad_save_user_regs

bl do_software_interrupt

.align 5

prefetch_abort:

get_bad_stack

bad_save_user_regs

bl do_prefetch_abort

.align 5

data_abort:

get_bad_stack

bad_save_user_regs

bl do_data_abort

.align 5

not_used:

get_bad_stack

bad_save_user_regs

bl do_not_used

#ifdef CONFIG_USE_IRQ

.align 5

irq:

get_irq_stack

irq_save_user_regs

bl do_irq

irq_restore_user_regs

.align 5

fiq:

get_fiq_stack

/* someone ought to write a more effiction fiq_save_user_regs */

irq_save_user_regs

bl do_fiq

irq_restore_user_regs

#else

.align 5

irq:

get_bad_stack

bad_save_user_regs

bl do_irq

.align 5

fiq:

get_bad_stack

bad_save_user_regs

bl do_fiq

#endif /*CONFIG_USE_IRQ*/

@可知start.S的流程为：异常向量——上电复位后进入复位异常向量——跳到启动代码处——设置处理器
进入管理模式——关闭看门狗——关闭中断——设置时钟分频——关闭MMU和CACHE——进入lowlever_init.S——检查当前代码所处的位
置，如果在FLASH中就将代码搬移到RAM中