ORACLE PL/SQL游标(cursor)学习笔记

declare

v_department classes.department%type;

v_course classes.course%type;

cursor c_classes is

select * from classes

where department=v_department

and course=v_course;

--上面这个游标包含了两个变量。我们可以将它修改为一个等价的参数化游标。

declare

cursor c_classes(p_department classes.department%type,p_course classes.course%type) is

select * from classes

where department=v_department

and course=v_course;

--借助于参数化游标，OPEN语句可以用于将实际数值传递给游标。

open c_classes('HIS',101);

--例如，下面的块在UPDATE语句没有找到任何行的时候就执行一条INSERT语句。

begin

update rooms

set number_seats=100

where room_id=99980;

--如果UPDATE语句没有找到任何行的时候就执行一条INSERT语句

if SQL%NOTFOUND then

insert into rooms(room_id,number_seats)

values(99980,100);

end if;

end;

--这个块将更新所有在HIS 101注册的学生的当前成绩
DECLARE
-- Number of credits to add to each student's total
v_NumCredits  classes.num_credits%TYPE;

-- This cursor will select only those students who are currently
-- registered for HIS 101.
CURSOR c_RegisteredStudents IS
SELECT *
FROM students
WHERE id IN (SELECT student_id
FROM registered_students
WHERE department= 'HIS'
AND course = 101)
FOR UPDATE OF current_credits;

BEGIN
-- Set up the cursor fetch loop.
FOR v_StudentInfo IN c_RegisteredStudents LOOP
-- Determine the number of credits for HIS 101.
SELECT num_credits
INTO v_NumCredits
FROM classes
WHERE department = 'HIS'
AND course = 101;

-- Update the row we just retrieved from the cursor.
UPDATE students
SET current_credits = current_credits + v_NumCredits
WHERE CURRENT OF c_RegisteredStudents;
END LOOP;

-- Commit our work.
COMMIT;
END;
/

--这个例子就将引发这个错误
DECLARE
-- Cursor to retrieve all students, and lock the rows as well.
CURSOR c_AllStudents IS
SELECT *
FROM students
FOR UPDATE;

-- Variable for retrieved data.
v_StudentInfo  c_AllStudents%ROWTYPE;
BEGIN
-- Open the cursor. This will acquire the locks.
OPEN c_AllStudents;

-- Retrieve the first record.
FETCH c_AllStudents INTO v_StudentInfo;

-- Issue a COMMIT. This will release the locks, invalidating the
-- cursor.
COMMIT WORK;

-- This FETCH will raise the ORA-1002 error.
FETCH c_AllStudents INTO v_StudentInfo;
END;
/

DECLARE
-- Number of credits to add to each student's total
v_NumCredits  classes.num_credits%TYPE;

-- This cursor will select only those students who are currently
-- registered for HIS 101.
CURSOR c_RegisteredStudents IS
SELECT *
FROM students
WHERE id IN (SELECT student_id
FROM registered_students
WHERE department= 'HIS'
AND course = 101);

BEGIN
-- Set up the cursor fetch loop.
FOR v_StudentInfo IN c_RegisteredStudents LOOP
-- Determine the number of credits for HIS 101.
SELECT num_credits
INTO v_NumCredits
FROM classes
WHERE department = 'HIS'
AND course = 101;

-- Update the row we just retrieved from the cursor.
UPDATE students
SET current_credits = current_credits + v_NumCredits
WHERE id = v_Studentinfo.id;

-- We can commit inside the loop, since the cursor is
-- not declared FOR UPDATE.
COMMIT;
END LOOP;
END;
/

--非受限游标的例子

CREATE OR REPLACE PROCEDURE ShowCursorVariable
/* Demonstrates the use of a cursor variable on the server.
If p_Table is 'classes', then information from the classes
table is inserted into temp_table.  If p_Table is 'rooms'
then information from rooms is inserted. */
(p_Table IN VARCHAR2) AS

/* Define the cursor variable type */
TYPE t_ClassesRooms IS REF CURSOR;

/* and the variable itself. */
v_CursorVar t_ClassesRooms;

/* Variables to hold the output. */
v_Department  classes.department%TYPE;
v_Course      classes.course%TYPE;
v_RoomID      rooms.room_id%TYPE;
v_Description rooms.description%TYPE;
BEGIN
-- Based on the input parameter, open the cursor variable.
IF p_Table = 'classes' THEN
OPEN v_CursorVar FOR
SELECT department, course
FROM classes;
ELSIF p_table = 'rooms' THEN
OPEN v_CursorVar FOR
SELECT room_id, description
FROM rooms;
ELSE
/* Wrong value passed as input - raise an error */
RAISE_APPLICATION_ERROR(-20000,
'Input must be ''classes'' or ''rooms''');
END IF;

/* Fetch loop.  Note the EXIT WHEN clause after the FETCH -
with PL/SQL 2.3 we can use cursor attributes with cursor
variables. */
LOOP
IF p_Table = 'classes' THEN
FETCH v_CursorVar INTO
v_Department, v_Course;
EXIT WHEN v_CursorVar%NOTFOUND;

INSERT INTO temp_table (num_col, char_col)
VALUES (v_Course, v_Department);
ELSE
FETCH v_CursorVar INTO
v_RoomID, v_Description;
EXIT WHEN v_CursorVAR%NOTFOUND;

INSERT INTO temp_table (num_col, char_col)
VALUES (v_RoomID, SUBSTR(v_Description, 1, 60));
END IF;
END LOOP;

/* Close the cursor. */
CLOSE v_CursorVar;

COMMIT;
END ShowCursorVariable;
/