游戏制作－－场景移动之二

自从那篇游戏场景移动之一后，现在我们制作另一种场景移动的方式。这次我们要做的形式就是当游戏角色超出一定范围后才滚动场景。
这种方式需要我们先给出一个角色可以移动的范围，只要游戏角色一超出这个范围地图就开始移动。知道相关的东西后我们就开始编写脚本把，其实我们不用再重新写一遍这个脚本，只要用我在第一篇提供的源码上作修改就能够容易地得出这种方式的场景移动了，那我们现在来看源代码吧：
import flash.geom.Rectangle;
//引入矩形类包

var rect:Rectangle = new Rectangle(50, 50, Stage.width-100, Stage.height-100);
var speed:Number = 3;
this.onEnterFrame = function() {
if (Key.isDown(Key.UP)) {
if (curPoint._y<=rect.top) {
if (map._y>=0) {
//到达上边界
map._y = 0;
curPoint._y -= speed;
} else {
map._y += speed;
}
} else {
curPoint._y -= speed;
}
}
if (Key.isDown(Key.DOWN)) {
if (curPoint._y>=rect.bottom) {
if (map._y<=-(map._height-Stage.height)) {
map._y = -(map._height-Stage.height);
curPoint._y += speed;
} else {
map._y -= speed;
}
} else {
curPoint._y += speed;
}
}
if (Key.isDown(Key.LEFT)) {
if (curPoint._x<=rect.left) {
if (map._x>=0) {
map._x = 0;
curPoint._x -= speed;
} else {
map._x += speed;
}
} else {
curPoint._x -= speed;
}
}
if (Key.isDown(Key.RIGHT)) {
if (curPoint._x>=rect.right) {
if (map._x<=-(map._width-Stage.width)) {
map._x = -(map._width-Stage.width);
curPoint._x += speed;
} else {
map._x -= speed;
}
} else {
curPoint._x += speed;
}
}
};
这就是所有的代码了，你可以按Ctrl+Enter来测试一下。
对于新手import flash.geom.Rectangle;这一句可能会感到疑惑，其实这是引入flash包的语句，Rectangle是矩形类，这次我们用了这个类来设定主角的移动范围。要源文件的请给出邮箱，我发给他。