vfp的数据库（.dbc）如何连接access（.mdb）？

vfp的数据库（.dbc）如何连接access（.mdb）?
我的目的是：将vfp数据库的多个表，进行多表查询，然后将结果保存到access的一个表中。该如何？

网友一：

1、在DBC中建立远程视图连接MDB（首先配置ODBC），再导数据；
2、用SPT、ADO连接MDB，将数据导入MDB。

网友二：

----------DBF 导入 ACCESS----------

方法一：用ACCESS中“文件”－>“获取外部数据”－>“导入”
参考： http://access911.net/eg/swf/importDBF.htm http://access911.net/eg/swf/importDBF.swf

用此种方法有时会提示“外部表不是预期的格式”，如果提示这错误，用以下方法解决：
1、用VFP打开DBF表，然后COPY TO NEWTABLE TYPE FOX2X，然后再用此方法把NEWTABLE导入试试。
2、改用ACCESS2003。

方法二：用ACCESS中“文件”－>“获取外部数据”－>“导入”，然后文件类型选择ODBC Database()，然后选择 <机器数据源>，
点击“新建”来建立一个数据源，数据源类型用“用户数据源”或“系统数据源”（建议用后者），然后点击“下一步”，
驱动程序选择‘Microsoft Visual FoxPro Driver’，点击“下一步”，点击“完成”，
在Data Source Name（数源源名称）处输入此数据源名称，可自定，本例如LjDbf，Database Type（数据库类型）处
选择“Free Table directory”(自由表路径)，然后在下面的Path（路径）处设置你要导入的DBF表所在的路径，本列如“D:/” ，
点击“确定”关闭数据源配制窗口，然后在“导入对象”窗口选择你要导入的DBF表，最后点击“确定”即可。

方法三：用VFP连接ACCESS，然后用代码把DBF数据一条一条写入ACCESS。就像写入SQL一样

方法四：如果你安装了SQL Server，可以用SQL Server的导入导出数据（DTS）来进行，因为DTS有向导，这里不做介绍。

方法五：先把DBF转成EXCEL或TXT，然再用方法一进行导入。
注：DBF表如果不含用备注字段，直接用COPY TO 表名.XLS type xl5 转成EXCEL，如果含用备注型字段，必须用下面方法转成EXCEL：

****DBFTOEXCEL.PRG****

CLOSE DATABASES ALL
SET DATE YMD
SET CENTURY ON
cDbfFile = GETFILE("dbf")
IF EMPTY(cDbfFile)
RETURN
ENDIF
USE (cDbfFile) ALIAS FoxTable IN 0
IF NOT USED("FoxTable")
=MESSAGEBOX("打开表失败，程序将中止！", 16, "Error")
RETURN
ENDIF
cExcelFile = PUTFILE("保存为(&N):",JUSTSTEM(cDbfFile)+".xls","xls")
IF EMPTY(cExcelFile)
CLOSE DATABASES ALL
RETURN
ENDIF
SELECT FoxTable
oExcelSheet = GETOBJECT("","Excel.Sheet") && 产生Excel对象
IF NOT TYPE("oExcelSheet") = "O"
=MESSAGEBOX("Excel对象创建失败，程序将中止！", 16, "Error")
RETURN
ENDIF
oExcelApp = oExcelSheet.APPLICATION
oExcelApp.Workbooks.ADD()
oExcelApp.ActiveWindow.WINDOWSTATE=2
oSheet = oExcelApp.ActiveSheet
nFldCount = AFIELDS(aFldList, "FoxTable")
FOR i = 1 TO nFldCount
oSheet.Cells(1,i).VALUE = aFldList[i, 1]
ENDFOR
cRecc = STR(RECCOUNT("FoxTable"))
SCAN
WAIT WINDOW ALLTRIM(STR(RECNO())) + "/" + cRecc NOWAIT
FOR i = 1 TO nFldCount
vValue = .NULL.
IF AT(aFldList[i, 2], "CDLMNFIBYT") = 0
LOOP
ENDIF
cFldName = aFldList[i, 1]
vValue = EVALUATE(cFldName)
DO CASE
CASE aFldList[i, 2] = "C" && 字符/字符串
vValue = TRIM(vValue)
CASE aFldList[i, 2] = "D" && 日期
vValue = DTOC(vValue)
CASE aFldList[i, 2] = "T" && 日期时间
vValue = TTOC(vValue)
CASE INLIST(aFldList[i, 2], "N", "F", "I", "B", "Y") && 数值
CASE aFldList[i, 2] = "L" && 逻辑
CASE aFldList[i, 2] = "M" && 备注型
OTHERWISE
vValue = .NULL.
ENDCASE
IF VARTYPE(vValue) = "C" AND EMPTY(vValue)
LOOP
ENDIF
IF NOT ISNULL(vValue)
oSheet.Cells(RECNO("FoxTable")+1, i).VALUE = vValue
ENDIF
ENDFOR
ENDSCAN
cChrStr = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
FOR i = 1 TO nFldCount
cColumn = SUBSTR(cChrStr, INT((i-1)/26), 1) + SUBSTR(cChrStr, IIF(MOD(i, 26)= 0, 26, MOD(i, 26)) , 1)
oSheet.COLUMNS(cColumn + ":" + cColumn).COLUMNWIDTH = 12
IF aFldList[i, 2] = "M"
oSheet.COLUMNS(cColumn + ":" + cColumn).WrapText = .F.
ENDIF
ENDFOR
oExcelApp.ActiveWorkbook.SAVEAS(cExcelFile)
oExcelApp.ActiveWorkbook.CLOSE(.F.)
oExcelApp.ActiveWorkbook.CLOSE(.F.)
oExcelApp.QUIT
oExcelSheet = .NULL.
oExcelApp = .NULL.
WAIT CLEAR
=MESSAGEBOX("转换完毕！", 64, "OK")
CLOSE DATABASES ALL

方法三：用VFP连接ACCESS，然后用代码把DBF数据一条一条写入ACCESS。就像写入SQL一样

请参考：

A：需配ODBC数据数据源
*---------------------------
&&ODBC的配制方法在这里不再介绍，以下finger3为数据源名
nhandle=SQLCONNECT("finger3",'','密码')
IF nhandle <0
MESSAGEBOX("数据库连接失败！！！",16, '错误信息')
RETURN
ELSE
Ac=SQLEXEC(nhandle,"Select * From worker_info","Temp1")
IF Ac <0
MESSAGEBOX("读取数据错误！",16, '错误信息')
RETURN
ENDIF
SELECT Temp1
BROWSE
ENDIF

B：无需配ODBC数据数据源，即用字符串方式连接
*-------------------------------
nhandle=SQLSTRINGCONNECT("Driver={Microsoft Access Driver (*.mdb)};dbq=c:/test.mdb;pwd=") &&pwd为数据库密码项
IF nhandle <=0
MESSAGEBOX("数据库连接失败！！！",16, '错误信息')
RETURN
ELSE
Ac=SQLEXEC(nhandle,"Select * From worker_info","Temp1")
IF Ac <0
MESSAGEBOX("读取数据错误！",16, '错误信息')
RETURN
ENDIF
SELECT Temp1
BROWSE
ENDIF

将上面的Select 语句改为Sacn+Insert

网友三：

用ADO分别连接两个数据库,然后把VFP中的数据读取到记录集,循环访问记录集,把记录写入ACCESS所在的数据库连接即可..
ADO的文章,参考: http://www.vckbase.com/document/viewdoc/?id=1215 http://www.vckbase.com/document/viewdoc/?id=610