判断主表的子表下是否存在相应记录

if exists(select name from sysobjects
where name='HaveRecord' and type in ('P'))
drop proc HaveRecord
go
CREATE proc HaveRecord
@tbname sysname,-- 基础数据表名
@PkFieldName sysname,-- 基础数据表关键字段名
@PkValue varchar(100),-- 要删除的基础数据表关键字值
@isHave bit output

AS
begin
set @isHave = 0
DECLARE @flag bit, @s nvarchar(4000)
declare @bzs int
set @bzs=0
DECLARE tb CURSOR LOCAL --开始建立游标
FOR

--以下查询是找到与其相关联的子表，建立与相应字段相等的查询语句
SELECT N'
SET @flag = CASE WHEN EXISTS(
SELECT * FROM ' + QUOTENAME(@tbname)
+ N' A, ' + QUOTENAME(OBJECT_NAME(B.fkeyid))
+ N' B
WHERE A.' + QUOTENAME((SELECT name FROM syscolumns WHERE colid = B.rkey AND id = B.rkeyid))
+ N' = B.' + QUOTENAME((SELECT name FROM syscolumns WHERE colid = B.fkey AND id = B.fkeyid))
+ N' AND A.' + QUOTENAME((SELECT name FROM syscolumns WHERE colid = B.rkey AND id = B.rkeyid))
+ N' = @id) THEN 1 ELSE 0 END '
FROM sysobjects A
JOIN sysforeignkeys B
ON A.id= B.constid
JOIN sysobjects C
ON A.parent_obj = C.id
WHERE A.xtype = 'f'
AND C.xtype = 'U'
AND OBJECT_NAME(B.rkeyid) = @tbname --游标结束

OPEN tb --打开游标
FETCH tb INTO @s --判断游标是正确
WHILE @@FETCH_STATUS = 0
BEGIN
--查询每个子表中是否存在记录，如果有则@flag返回1，否则返回0

EXEC sp_executesql @s, N'@id varchar(100), @flag bit OUTPUT', @PkValue, @flag OUTPUT

IF @flag = 1
BEGIN
set @bzs=@bzs+1 --如果子中有记录则加1
END
FETCH tb INTO @s
END
CLOSE tb --关闭游标
DEALLOCATE tb --释放游标
if @bzs > 0 --子表中有记录，否则为没有记录
begin
set @isHave = 1
end
end