函数调用约定

今天在C#调用C++ DLL的时候出现了一些问题，后来追查了下去，原来是函数的调用约定出了问题。
调用约定（Calling Convention）是指在程序设计语言中为了实现函数调用而建立的一种协议。这种协议规定了该语言的函数中的参数传送方式、参数是否可变和由谁来处理堆栈等问题。不同的语言定义了不同的调用约定。
在C++中，因为重载的原因，所以对函数的命名方式和普通C语言并不一致，该方式称为名字改编。为了支持跨语言调用，特此出现双方协商的调用约定，以保证跨语言接口调用的成功。
约定一：__cdecl
__cdecl是C/C++和MFC程序默认使用的调用约定，也可以在函数声明时加上__cdecl关键字来手工指定。采用__cdecl约定时，函数参 数按照从右到左的顺序入栈，并且由调用函数者把参数弹出栈以清理堆栈。因此，实现可变参数的函数只能使用该调用约定。由于每一个使用__cdecl约定的 函数都要包含清理堆栈的代码，所以产生的可执行文件大小会比较大。__cdecl可以写成_cdecl。（函数调用处清栈）
下面将通过一个具体实例来分析__cdecl约定：
在VC++中新建一个Win32 Console工程，命名为cdecl。其代码如下：
int __cdecl Add(int a, int b); //函数声明
void main()
{
Add(1,2); //函数调用
}
int __cdecl Add(int a, int b) //函数实现
{
return (a + b);
}
函数调用处反汇编代码如下：
;Add(1,2);
push 2 ;参数从右到左入栈，先压入2
push 1 ;压入1
call @ILT+0(Add) (00401005) ;调用函数实现
add esp,8 ;由函数调用清栈
约定二：__stdcall
__stdcall调用约定用于调用Win32 API函数。采用__stdcal约定时，函数参数按照从右到左的顺序入栈，被调用的函数在返回前清理传送参数的栈，函数参数个数固定。由于函数体本身知道传进来的参数个数，因此被调用的函数可以在返回前用一条ret n指令直接清理传递参数的堆栈。__stdcall可以写成_stdcall。（被调函数清栈）
还是那个例子，将__cdecl约定换成__stdcall：
int __stdcall Add(int a, int b)
{
return (a + b);
}
函数调用处反汇编代码：
; Add(1,2);
push 2 ;参数从右到左入栈，先压入2
push 1 ;压入1
call @ILT+10(Add) (0040100f) ;调用函数实现
函数实现部分的反汇编代码：
;int __stdcall Add(int a, int b)
push ebp
mov ebp,esp
sub esp,40h
push ebx
push esi
push edi
lea edi,[ebp-40h]
mov ecx,10h
mov eax,0CCCCCCCCh
rep stos dword ptr [edi]
;return (a + b);
mov eax,dword ptr [ebp+8]
add eax,dword ptr [ebp+0Ch]
pop edi
pop esi
pop ebx
mov esp,ebp
pop ebp
ret 8 ;清栈
约定三：__fastcall
__fastcall约定用于对性能要求非常高的场合。__fastcall约定将函数的从左边开始的两个大小不大于4个字节（DWORD）的参数 分别放在ECX和EDX寄存器，其余的参数仍旧自右向左压栈传送，被调用的函数在返回前清理传送参数的堆栈。__fastcall可以写成 _fastcall。
依旧是相类似的例子，此时函数调用约定为__fastcall，函数参数个数增加2个：
int __fastcall Add(int a, double b, int c, int d)
{
return (a + b + c + d);
}
函数调用部分的汇编代码：
;Add(1, 2, 3, 4);
push 4 ;后两个参数从右到左入栈，先压入4
mov edx,3 ;将int类型的3放入edx
push 40000000h ;压入double类型的2
push 0
mov ecx,1 ;将int类型的1放入ecx
call @ILT+0(Add) (00401005) ;调用函数实现
函数实现部分的反汇编代码：

; int __fastcall Add(int a, double b, int c, int d)
push ebp
mov ebp,esp
sub esp,48h
push ebx
push esi
push edi
push ecx
lea edi,[ebp-48h]
mov ecx,12h
mov eax,0CCCCCCCCh
rep stos dword ptr [edi]
pop ecx
mov dword ptr [ebp-8],edx
mov dword ptr [ebp-4],ecx
;return (a + b + c + d);
fild dword ptr [ebp-4]
fadd qword ptr [ebp+8]
fiadd dword ptr [ebp-8]
fiadd dword ptr [ebp+10h]
call __ftol (004011b8)
pop edi
pop esi
pop ebx
mov esp,ebp
pop ebp
ret 0Ch ;清栈
关键字__cdecl、__stdcall和__fastcall可以直接加在要输出的函数前，也可以在编译环境的Setting...-> C/C++->Code Generation项选择。它们对应的命令行参数分别为/Gd、/Gz和/Gr。缺省状态为/Gd，即__cdecl。当加在输出函数前的关键字与编译 环境中的选择不同时，直接加在输出函数前的关键字有效。

约定四：thiscall
thiscall调用约定是C++中的非静态类成员函数的默认调用约定。thiscall只能被编译器使用，没有相应的关键字，因此不能被程序员指定。采用thiscall约定时，函数参数按照从右到左的顺序入栈，被调用的函数在返回前清理传送参数的栈，只是另外通过 ECX寄存器传送一个额外的参数：this指针。
这次的例子中将定义一个类，并在类中定义一个成员函数，代码如下：
class CSum
{
public:
int Add(int a, int b)
{
return (a + b);
}
};
void main()
{
CSum sum;
sum.Add(1, 2);
}
函数调用部分汇编代码：
;CSum sum;
;sum.Add(1, 2);
push 2 ;参数从右到左入栈，先压入2
push 1 ;压入1
lea ecx,[ebp-4] ;ecx存放了this指针
call @ILT+5(CSum::Add) (0040100a) ;调用函数实现
函数实现部分汇编代码：
;int Add(int a, int b)
push ebp
mov ebp,esp
sub esp,44h ;多用了一个4bytes的空间用于存放this指针
push ebx
push esi
push edi
push ecx
lea edi,[ebp-44h]
mov ecx,11h
mov eax,0CCCCCCCCh
rep stos dword ptr [edi]
pop ecx
mov dword ptr [ebp-4],ecx
;return (a + b);
mov eax,dword ptr [ebp+8]
add eax,dword ptr [ebp+0Ch]
pop edi
pop esi
pop ebx
mov esp,ebp
pop ebp
ret 8 ;清栈

约定五：naked属性
采用上面所述的四种调用约定的函数在进入函数时，编译器会产生代码来保存ESI、EDI、EBX、EBP寄存器中的值，退出 函数时则产生代码恢复这些寄存器的内容。对于定义了naked属性的函数，编译器不会自动产生这样的代码，需要你手工使用内嵌汇编来控制函数实现中的堆栈 管理。由于naked属性并不是类型修饰符，故必须和__declspec共同使用。下面的这段代码定义了一个使用了naked属性的函数及其实现：
__declspec ( naked ) func()
{
int i;
int j;

_asm
{
push ebp
mov ebp, esp
sub esp, __LOCAL_SIZE
}

_asm
{
mov esp, ebp
pop ebp
ret
}
}
naked属性与本节关系不大，具体请参考MSDN。
约定六：WINAPI
还有一个值得一提的是WINAPI宏，它可以被翻译成适当的调用约定以供函数使用。该宏定义于windef.h之中。下面是在windef.h中的部分内容：
#define CDECL _cdecl
#define WINAPI CDECL
#define CALLBACK __stdcall
#define WINAPI __stdcall
#define APIENTRY WINAPI
由此可见，WINAPI、CALLBACK、APIENTRY等宏的作用。

名称修饰
C或C++函数在内部（编译和链接）通过修饰名（Decoration Name）识别。函数的修饰名是编译器在编译函数定义或者原型时生成的字符串。编译器在创建.obj文件时对函数名称进行修饰。有些情况下使用函数的修饰 名是必要的，如在模块定义文件里头指定输出C++重载函数、构造函数、析构函数，又如在汇编代码里调用C或C++函数等。
在VC++中，函数修饰名由编译类型（C或C++）、函数名、类名、调用约定、返回类型、参数等多种因素共同决定。下面分C编译、C++编译（非类成员函数）和C++类及其成员函数编译三种情况说明：
1、C编译时函数名称修饰
当函数使用__cdecl调用约定时，编译器仅在原函数名前加上一个下划线前缀，格式为_functionname。例如：函数int __cdecl Add(int a, int b)，输出后为：_Add。
当函数使用__stdcall调用约定时，编译器在原函数名前加上一个下划线前缀，后面加上一个@符号和函数参数的字节数，格式为 _functionname@number。例如：函数int __stdcall Add(int a, int b)，输出后为：_Add@8。
当函数是用__fastcall调用约定时，编译器在原函数名前加上一个@符号，后面是加一个@符号和函数参数的字节数，格式为 @functionname@number。例如：函数int __fastcall Add(int a, int b)，输出后为：@Add@8。
以上改变均不会改变原函数名中的字符大小写。

本文绝大多数引用蛋塔大陆的相关文章，特此声明。